Jenkinsfile.generate

library(
  identifier: 'jenkins-shared-library@master',
  retriever: modernSCM(
    [
      $class: 'GitSCMSource',
      remote: 'https://github.com/dhanarab/jenkins-pipeline-library.git'
    ]
  )
)

bitbucketCredentialsHttps = "bitbucket-build-extend-https"
bitbucketCredentialsSsh = "bitbucket-build-extend-ssh"
bitbucketCommitHref = null

sdkSpecRepoName = "justice-codegen-sdk-spec"
sdkCodegenRepoName = "justice-codegen-modular-sdk"
mockServerRepoName = "justice-codegen-sdk-mock-server"
sdkRepoName = "justice-codegen-python-modular-sdk"

sdkCodegenGenerateBranchName = "master"
sdkGenerateBranchName = "rc-nightly"

sdkSpecCommitHash = null
sdkCommitHash = null

sdkSpecPath = null
sdkCodegenPath = null
mockServerPath = null
sdkPath = null

sdkCodegenExe = "accelbyte-codegen-linux_amd64"

breakingChangeCheckExitCode = 0
outstandingDeprecationCount = 0

jobChannel = env.SLACK_CHANNEL_ACTIVITY_EXTEND_CODEGEN_MODULAR_SDK ? env.SLACK_CHANNEL_ACTIVITY_EXTEND_CODEGEN_MODULAR_SDK : "#activity-justice-codegen-modular-sdk"

def getTimestampUtc() {
  now = new Date()
  return now.format("yyyy-MM-dd'T'HH:mm:ss+00:00", TimeZone.getTimeZone('UTC'))
}

pipeline {
  agent {
    label "extend-builder-batch"
  }

  stages {
    // -------------------------------------- Prepare --------------------------------------
    stage("Prepare") {
      steps {
        script {
          sdkCodegenPath = "${env.WORKSPACE}/${sdkCodegenRepoName}"
          mockServerPath = "${env.WORKSPACE}/${mockServerRepoName}"
          sdkSpecPath = "${env.WORKSPACE}/${sdkSpecRepoName}"
          sdkPath = "${env.WORKSPACE}/${sdkRepoName}"

          sh "rm -rf ${sdkCodegenRepoName}"
          sh "rm -rf ${mockServerRepoName}"
          sh "rm -rf ${sdkSpecRepoName}"

          sshagent(credentials: [bitbucketCredentialsSsh]) {
            sh "git clone --branch ${sdkCodegenGenerateBranchName} --depth 1 git@bitbucket.org:accelbyte/${sdkCodegenRepoName}.git ${sdkCodegenPath}"
            sh "git clone --depth 1 git@bitbucket.org:accelbyte/${mockServerRepoName}.git ${mockServerPath}"
            sh "git clone --depth 50 git@bitbucket.org:accelbyte/${sdkSpecRepoName}.git ${sdkSpecPath}"
          }

          dir(sdkSpecPath) {
            sdkSpecCommitHash = sh(returnStdout: true, script: "git rev-list -1 HEAD spec/stage_extend-sdk/TIMESTAMP").trim()
          }
        }
      }
    }

    // -------------------------------------- Generate --------------------------------------
    stage("Generate SDK") {
      steps {
        sh "sudo apt install -y jq"

        // Setup generate branch
        dir(sdkRepoName) {
          sh "git branch ${sdkGenerateBranchName}"
          sh "git checkout ${sdkGenerateBranchName}"
        }

        // Copy latest OpenAPI spec from spec repository to SDK repository
        sh "rm -fv ${sdkPath}/spec/*"
        sh "find ${sdkSpecPath}/spec/stage_extend-sdk/ -maxdepth 1 -type f -exec cp -v -t ${sdkPath}/spec/ {} \\;"
        sh "cp -v ${sdkSpecPath}/docs/openapi-2.0-vendor-extensions.md ${sdkPath}/spec/"

        // Build Linux Executable
        dir(sdkCodegenPath) {
          sh script: "make build-linux", label: "Build Linux Executable"
        }

        // Generate SDK (SDK only)
        dir(sdkCodegenPath) {
          script {
            version = sh(returnStdout: true, script: " jq -r '.\"src/all\"' ${sdkPath}/sh/package.json").trim()
          }
          sh script: "cd templates/python-modular-extend-sdk && make sdk_all CODEGEN_PATH=${sdkCodegenPath}/${sdkCodegenExe} SDK_PATH=${sdkPath} SPEC_PATH=${sdkPath}/spec VERSION=${version}", label: "Generate SDK (SDK only)"
        }

        // Run CLI tests against the Mock Server
        dir(sdkPath) {
          script {
            breakingChangeCheckExitCode = sh script: "make test_cli SDK_MOCK_SERVER_PATH=${mockServerPath}", returnStatus: true, label: "Run CLI tests against the Mock Server"
          }
        }

        // Generate SDK (CLI, CLI tests, Docs, Style, Revision)
        dir(sdkCodegenPath) {
          sh script: "cd templates/python-modular-extend-sdk && make cli_cmd_all cli_test_all doc_index_all style revision CODEGEN_PATH=${sdkCodegenPath}/${sdkCodegenExe} SDK_PATH=${sdkPath} SPEC_PATH=${sdkPath}/spec", label: "Generate SDK (CLI, CLI tests, Docs, Style, Revision)"
        }

        // Bump SDK version and Commit the generated code to branch, overwrite existing
        dir(sdkPath) {
          sh "sudo apt install -y jq"
          sh "make bumpif_all"
          sh "git add --all"
          sh "git commit -m 'chore(sdk): generate python extend sdk (${getTimestampUtc()})' -m 'generated from openapi spec commit: ${sdkSpecCommitHash}'"

          sshagent(credentials: [bitbucketCredentialsSsh]) {
            sh "git push --set-upstream origin +${sdkGenerateBranchName}:${sdkGenerateBranchName}"
          }

          script {
            sdkCommitHash = git.getCommitHash()
            bitbucketCommitHref = "https://api.bitbucket.org/2.0/repositories/accelbyte/${sdkRepoName}/commit/${sdkCommitHash}"
            bitbucket.setBuildStatus(bitbucketCredentialsHttps, bitbucketCommitHref, "INPROGRESS", env.JOB_NAME.take(30), "${env.JOB_NAME}-${env.BUILD_NUMBER}", "Jenkins", "${env.BUILD_URL}console")
          }
        }

        // Check outstanding deprecation
        script {
          dir(sdkPath) {
            // Ignore exit code, just need the outstanding_deprecation.out file
            sh script: "make outstanding_deprecation || true", label: "Check outstanding deprecation"

            if (!fileExists('outstanding_deprecation.out')) {
              error("File 'outstanding_deprecation.out' is not found")
            }

            outstandingDeprecationCount = sh(returnStdout: true, script: "grep -c '^not ok' outstanding_deprecation.out || true").trim() as Integer
          }
        }
      }
    }

    // -------------------------------------- Tests --------------------------------------
    stage('Core Tests') {
      steps {
        dir(sdkRepoName) {
          sh "make test_core SDK_MOCK_SERVER_PATH=${mockServerPath}"
        }
      }
    }

    stage('CLI Tests') {
      steps {
        dir(sdkRepoName) {
          sh "make test_cli SDK_MOCK_SERVER_PATH=${mockServerPath}"
        }
      }
      post {
        always {
          script {
            dir(sdkRepoName) {
              archiveArtifacts artifacts: 'samples/cli/tests/*.tap'
              step([$class: "TapPublisher", testResults: "samples/cli/tests/*.tap"])
            }
          }
        }
      }
    }

    stage('Integration Tests') {
      options {
        lock("justice-demo-serversdktest")
      }
      environment {
        DEFAULT_IFACE = sh(script: 'ip route get 1.1.1.1 | awk \'NR==2 {print $1}\' RS=dev', returnStdout: true)
      }
      steps {
        dir(sdkRepoName) {
          sh 'sudo tc qdisc add dev $DEFAULT_IFACE root netem delay 100ms'    // Delay sending packets due to database eventual consistency
          withCredentials([
            file(credentialsId: 'justice-codegen-sdk-integration-test-env', variable: 'ENV_FILE_PATH'),
          ]) {
            sh 'make test_integration ENV_FILE_PATH=$ENV_FILE_PATH'
          }
        }
      }
      post {
        always {
          script {
            sh 'sudo tc qdisc del dev $DEFAULT_IFACE root netem delay 100ms'
            dir(sdkRepoName) {
              sh 'rm -f tests/integration/.env'
              archiveArtifacts artifacts: 'test_integration.tap'
              step([$class: "TapPublisher", testResults: "test_integration.tap"])
            }
          }
        }
      }
    }
  }

  post{
    success {
      script {
        if (bitbucketCommitHref != null) {
          bitbucket.setBuildStatus(bitbucketCredentialsHttps, bitbucketCommitHref, "SUCCESSFUL", env.JOB_NAME.take(30), "${env.JOB_NAME}-${env.BUILD_NUMBER}", "Jenkins", "${env.BUILD_URL}console")
        }

        additionalInfo = ""

        if (breakingChangeCheckExitCode != 0) {
          additionalInfo += """
              | :warning: Possible Breaking Changes Detected: <${env.BUILD_URL}/flowGraphTable/#:~:text=Check%20code%2Dlevel%20breaking%20changes|here>"""
        }

        if (outstandingDeprecationCount != 0) {
          additionalInfo += """
              | :warning: Outstanding Deprecation Detected: <${env.BUILD_URL}/flowGraphTable/#:~:text=Check%20outstanding%20deprecation|${outstandingDeprecationCount}>"""
        }

        specLink = "https://bitbucket.org/accelbyte/justice-codegen-sdk-spec/commits/${sdkSpecCommitHash}"
        sdkLink = "https://bitbucket.org/accelbyte/${sdkRepoName}/commits/${sdkCommitHash}"
        message = """
                  :white_check_mark: <${env.BUILD_URL}|${env.JOB_NAME}-${env.BUILD_NUMBER}> *Generate Python Extend SDK Successful :python:*

                  |*OpenAPI Spec:* <${specLink}|${sdkSpecCommitHash}>
                  |*Generated SDK:* <${sdkLink}|${sdkCommitHash}>

                  |<https://bitbucket.org/accelbyte/${sdkRepoName}/pull-requests/new?source=${sdkGenerateBranchName}|Compare or Create Pull Request>
                  ${additionalInfo}
                  |""".stripMargin()
        slackSend(channel: jobChannel, color: '#36B37E', message: message)
      }
    }
    failure {
      script {
        if (bitbucketCommitHref != null) {
          bitbucket.setBuildStatus(bitbucketCredentialsHttps, bitbucketCommitHref, "FAILED", env.JOB_NAME.take(30), "${env.JOB_NAME}-${env.BUILD_NUMBER}", "Jenkins", "${env.BUILD_URL}console")
        }

        message = """
            :no_entry: <${env.BUILD_URL}|${env.JOB_NAME}-${env.BUILD_NUMBER}> *failed*

            |""".stripMargin()
        slackSend(channel: jobChannel, color: '#FF0000', message: message)
      }
    }
  }
}