build.gradle

plugins {
    id "java"
    id "edu.wpi.first.GradleRIO" version "2024.3.1"
    id "maven-publish"
    id "eclipse"
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

group 'org.carlmontrobotics'

def ROBOT_MAIN_CLASS = ""

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project DeployUtils.
deploy {
    targets {
        roborio(getTargetTypeClass('RoboRIO')) {
            // Team number is loaded either from the .wpilib/wpilib_preferences.json
            // or from command line. If not found an exception will be thrown.
            // You can use getTeamOrDefault(team) instead of getTeamNumber if you
            // want to store a team number in this file.
            team = project.frc.getTeamNumber()
            debug = project.frc.getDebugOrDefault(false)

            artifacts {
                // First part is artifact name, 2nd is artifact type
                // getTargetTypeClass is a shortcut to get the class type using a string

                frcJava(getArtifactTypeClass('FRCJavaArtifact')) {
                }

                // Static files artifact
                frcStaticFileDeploy(getArtifactTypeClass('FileTreeArtifact')) {
                    files = project.fileTree('src/main/deploy')
                    directory = '/home/lvuser/deploy'
                }
            }
        }
    }
}

def deployArtifact = deploy.targets.roborio.artifacts.frcJava

// Set to true to use debug for JNI.
wpi.java.debugJni = false

// Set this to true to enable desktop support.
def includeDesktopSupport = true

// Defining my dependencies. In this case, WPILib (+ friends), and vendor libraries.
// Also defines JUnit 5.
dependencies {
    implementation wpi.java.deps.wpilib()
    implementation wpi.java.vendor.java()

    roborioDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.roborio)
    roborioDebug wpi.java.vendor.jniDebug(wpi.platforms.roborio)

    roborioRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.roborio)
    roborioRelease wpi.java.vendor.jniRelease(wpi.platforms.roborio)

    nativeDebug wpi.java.deps.wpilibJniDebug(wpi.platforms.desktop)
    nativeDebug wpi.java.vendor.jniDebug(wpi.platforms.desktop)
    simulationDebug wpi.sim.enableDebug()

    nativeRelease wpi.java.deps.wpilibJniRelease(wpi.platforms.desktop)
    nativeRelease wpi.java.vendor.jniRelease(wpi.platforms.desktop)
    simulationRelease wpi.sim.enableRelease()

    testImplementation 'junit:junit:4.13.2'

    implementation 'org.mockito:mockito-core:5.11.0'
    implementation group: 'org.apache.commons', name: 'commons-csv', version: '1.6'
}

// Simulation configuration (e.g. environment variables).
wpi.sim.addGui().defaultEnabled = true
wpi.sim.addDriverstation()

// Setting up my Jar File. 
jar {
    // Note: Do NOT add all the libraries to the jar. Doing so will cause robot programs to have
    // 2 copies of each of the libraries classes, one from lib199 and one from the robot program.
    from sourceSets.main.allSource

    // Add the manifest so WPILib knows where to look for our Robot Class.
    manifest edu.wpi.first.gradlerio.GradleRIOPlugin.javaManifest(ROBOT_MAIN_CLASS)

    // There shouldn't be any duplicate classes.
    duplicatesStrategy = DuplicatesStrategy.FAIL
}

publishing {
    publications {
        gpr(MavenPublication) {
            groupId = 'org.carlmontrobotics'
            artifactId = 'lib199'
            version = '4.0.2'

            from components.java
        }
    }
}

// Configure jar and deploy tasks
deployArtifact.jarTask = jar
wpi.java.configureExecutableTasks(jar)
wpi.java.configureTestTasks(test)

// Configure string concat to always inline compile
tasks.withType(JavaCompile) {
    options.compilerArgs.add '-XDstringConcat=inline'
}

// Allow the generated javadocs to link to the documentation of WPILib and vendor libraries
javadoc {
    options.with {
        links 'https://github.wpilib.org/allwpilib/docs/release/java/'
        links 'https://www.kauailabs.com/public_files/navx-mxp/apidocs/java/'
        links 'https://pathplanner.dev/api/java/'
        links 'https://api.ctr-electronics.com/phoenix/release/java/'
        links 'https://api.ctr-electronics.com/phoenix6/release/java/'
        links 'https://www.playingwithfusion.com/frc/2022/javadoc/'
        links 'https://codedocs.revrobotics.com/java/'
    }
}