build.gradle

/*
 * Copyright 2011-present Greg Shrago
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
  repositories {
    mavenCentral()
  }
}

plugins {
  id 'org.jetbrains.intellij' version "0.4.19"
}

version = "${version}"
defaultTasks 'clean', 'artifacts', 'test'

allprojects {
  apply plugin: 'java'
  sourceCompatibility = javaVersion
  targetCompatibility = javaVersion

  sourceSets {
    main {
      java.srcDirs 'src', 'gen'
      resources.srcDirs 'resources'
    }
    test {
      java.srcDir 'tests'
    }
  }
  apply plugin: 'idea'
  idea.module {
    generatedSourceDirs += file('gen')
  }
  apply plugin: 'org.jetbrains.intellij'
  intellij {
    version ideaVersion
    type 'IU'
    plugins 'uml', 'java'
    updateSinceUntilBuild false
  }
  buildSearchableOptions.enabled = false
}

test {
  useJUnit {}
  include '**/BnfTestSuite.class'
  scanForTestClasses false
  ignoreFailures true
}

apply from: 'artifacts.gradle'