Optimal Normal calculations

[TokisanGames]

From @Xtarsia

This is a new method for calculating normals in fragment()
the n1 - n4 values can be returned to use for correct blending when doing projection too. completley avoiding any need for a normal map 😄 #400, the original artifact #185 , and this new method (no vertex normals calculated at all)
the normals are more correctly centered too
with a single gather_texel_normal() we get the 1st image normals, handy for low-poly. 2nd is the smooth normals.

4x gathers is roughly equal to 1 full texture lookup (a wee bit more expensive)

I think this is a novel approach, i never found anything using gather to generate normals from heightmap on the fly in all my googling efforts.

This method means that the normal values don't exactly line up [with the vertices], im essentially magicking up a 1025th pixel

This method calculates normals at the center of a region vs at the edge:

// Calculates a normal from a single gather() call on a heightmap.
// The returned normal is derived at the exact center of the 4 texels.
// "0.25 lookups"
vec3 gather_texel_normal(vec2 uv2) {
    vec3 gather_uv = get_region_uv2(uv2);
    // ensure edge samples dont overshoot, align uv range over
    // center & correct for 0.5 Floating point error
    gather_uv.xy *= 1.0 - _region_texel_size;
    gather_uv.xy += _region_texel_size * 0.4989;
    vec4 g_texels = textureGather(_height_maps, gather_uv);
    float u = g_texels[3] - g_texels[2] + g_texels[0] - g_texels[1];
    float v = g_texels[3] - g_texels[0] + g_texels[2] - g_texels[1];
    return vec3(u, _mesh_vertex_spacing * 2.0 * (1.0 - _region_texel_size), v);
}

// "1 lookup"
vec3 get_normal(vec2 uv2) {
    // texel uv offsets
    vec2 uvs[4] = vec2[4](
        uv2 + vec2(0.0, _region_texel_size), uv2 + _region_texel_size,
        uv2 + vec2(_region_texel_size, 0.0), uv2
    );
    // Normals from each texel set
    vec3 n[4] = vec3[4](
        gather_texel_normal(uvs[0]), gather_texel_normal(uvs[1]),
        gather_texel_normal(uvs[2]), gather_texel_normal(uvs[3])
    );
    // flat normals
    //return normalize(n[3] + n[2] +n[0] +n[1]);
    
    // Bilinear weight between texels
    vec2 weight = fract(uv2 * (_region_size - 1.0));
    vec3 normal = normalize(mix(mix(n[3], n[2], weight.x), mix(n[0], n[1], weight.x), weight.y));
    return normal;
}