CMakeLists.txt

cmake_minimum_required(VERSION 3.12)
project(scapula NONE)

# Import CMake Modules
include(ExternalProject)

# Initialize top-level super build project
include(${CMAKE_SOURCE_DIR}/scripts/cmake/init_project.cmake)

# Download and build dependencies
include(${SCAPULA_SOURCE_DEPENDS_DIR}/dtc.cmake)
include(${SCAPULA_SOURCE_DEPENDS_DIR}/libfdt.cmake)
include(${SCAPULA_SOURCE_DEPENDS_DIR}/meson.cmake)
include(${SCAPULA_SOURCE_DEPENDS_DIR}/libc.cmake)
include(${SCAPULA_SOURCE_DEPENDS_DIR}/libmemory.cmake)
include(${SCAPULA_SOURCE_DEPENDS_DIR}/xml_specs.cmake)
include(${SCAPULA_SOURCE_DEPENDS_DIR}/shoulder.cmake)

# Generate testcase source code
add_subproject(
    scapula
    DEPENDS shoulder
    DEPENDS sysreg_spec
    DEPENDS a64_spec
    DEPENDS a32_spec
    SOURCE_DIR ${SCAPULA_SOURCE_ROOT_DIR}/scapula
    INSTALL_PREFIX ${SCAPULA_AARCH64_INSTALL_PREFIX}
)

# Build the 64-bit Scapula OS testcase runtime environment
add_subproject(
    scapula_os_aarch64
    DEPENDS shoulder
    DEPENDS libc
    DEPENDS libmemory
    SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/scapula_os/src
    TOOLCHAIN ${SCAPULA_SOURCE_CMAKE_DIR}/toolchain/aarch64-linux-gnu-gcc.cmake
    INSTALL_PREFIX ${SCAPULA_AARCH64_INSTALL_PREFIX}
)

# Build the 32-bit Scapula OS testcase runtime environment
add_subproject(
    scapula_os_aarch32
    DEPENDS shoulder
    DEPENDS libc
    DEPENDS libmemory
    SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/scapula_os/src
    TOOLCHAIN ${SCAPULA_SOURCE_CMAKE_DIR}/toolchain/arm-linux-gnueabihf-gcc.cmake
    INSTALL_PREFIX ${SCAPULA_AARCH32_INSTALL_PREFIX}
)

# Build aarch32 testcases that were generated by scapula
add_subproject(
    test_cases_aarch32
    DEPENDS shoulder
    DEPENDS scapula_os_aarch32
    DEPENDS scapula
    SOURCE_DIR ${SCAPULA_SOURCE_ROOT_DIR}/scripts/cmake/build_generated/aarch32
    TOOLCHAIN ${SCAPULA_SOURCE_CMAKE_DIR}/toolchain/arm-linux-gnueabihf-gcc.cmake
    INSTALL_PREFIX ${SCAPULA_AARCH32_INSTALL_PREFIX}
)

# Build aarch64 testcases that were generated by scapula
add_subproject(
    test_cases_aarch64
    DEPENDS shoulder
    DEPENDS scapula_os_aarch64
    DEPENDS scapula
    SOURCE_DIR ${SCAPULA_SOURCE_ROOT_DIR}/scripts/cmake/build_generated/aarch64
    TOOLCHAIN ${SCAPULA_SOURCE_CMAKE_DIR}/toolchain/aarch64-linux-gnu-gcc.cmake
    INSTALL_PREFIX ${SCAPULA_AARCH64_INSTALL_PREFIX}
)

# Bundle up all of the above as a .fit image contained in a linkable archive
add_subproject(
    images
    DEPENDS dtc
    DEPENDS test_cases_aarch32
    DEPENDS test_cases_aarch64
    SOURCE_DIR ${SCAPULA_SOURCE_ROOT_DIR}/scripts/cmake/build_generated/images
    TOOLCHAIN ${SCAPULA_SOURCE_CMAKE_DIR}/toolchain/aarch64-linux-gnu-gcc.cmake
    INSTALL_PREFIX ${SCAPULA_AARCH64_INSTALL_PREFIX}
)

# Build the Scapula Loader
add_subproject(
    scapula_loader
    DEPENDS dtc
    DEPENDS libfdt
    DEPENDS shoulder
    DEPENDS scapula_os_aarch64
    DEPENDS images
    SOURCE_DIR ${CMAKE_CURRENT_LIST_DIR}/scapula_loader
    TOOLCHAIN ${SCAPULA_SOURCE_CMAKE_DIR}/toolchain/aarch64-linux-gnu-gcc.cmake
    INSTALL_PREFIX ${SCAPULA_AARCH64_INSTALL_PREFIX}
)

print_banner()
print_usage()