build.gradle

plugins {
    alias libs.plugins.dependencycheck
    alias libs.plugins.errorprone
    alias libs.plugins.versions
}

def isNonStable = { String version ->
    def stableKeyword = ['RELEASE', 'FINAL', 'GA'].any { it -> version.toUpperCase().contains(it) }
    def regex = /^[0-9,.v-]+(-r)?$/
    return !stableKeyword && !(version ==~ regex)
}

dependencyCheck {
    scanConfigurations = ['runtimeClasspath']
}

subprojects {
    apply plugin: "java"
    apply plugin: 'com.github.ben-manes.versions'
    apply plugin: 'net.ltgt.errorprone'

    java {
        targetCompatibility = JavaVersion.VERSION_17
        sourceCompatibility = JavaVersion.VERSION_17
    }

    repositories {
        mavenCentral()
    }

    // Reject all non stable versions in dependency check
    tasks.named("dependencyUpdates").configure {
        rejectVersionIf {
            isNonStable(it.candidate.version)
        }
    }

    // Standard libraries added to all projects
    dependencies {
        errorprone(libs.errorprone.core)
        compileOnly libs.errorprone.annotations

        testImplementation libs.junit
        testImplementation libs.mockito.core

        implementation libs.slf4j.api
    }

}