How can i get (Mode/FanSpeed/Temp) from IRrecv results after decoding

[LionKKK]

Great library, everything works. But I'm stuck on a small problem. I want to receive the statuses encoded in the IR remote separately.
part of my code:

IRrecv irrecv(kRecvPin, kCaptureBufferSize, kTimeout, true); decode_results results;


void setup() {
irrecv.enableIRIn();
Serial.begin(74880);
  delay(200);
}


void loop() {
if (irrecv.decode(&results)) {
    Serial.println(resultToHexidecimal(&results)); // 0x2C09205000200010
    Serial.println(IRAcUtils::resultAcToString(&results)); // Model: 2 (YBOFB), Power: On, Mode: 4 (Heat), Temp: 25C, Fan: 2 (Medium) .....

}
}

how can i get only "Mode" or only "Fan" from "results"?

[crankyoldgit]

Serial.begin(74880);

First off, I noticed the above, you should check out: https://github.com/crankyoldgit/IRremoteESP8266/wiki/Frequently-Asked-Questions#user-content-Some_of_the_examples_dont_produce_output_that_I_expect_and_I_have_to_use_a_baud_rate_of_74880_Whats_up

Your board needs to be fixed, or replaced.

Next, how to get specific aspects of an AC message in a programatic way ...
See:

IRremoteESP8266/test/ir_Daikin_test.cpp

Lines 3824 to 3837 in 9bdf8ab

	// Test some real codes.
	// Ref: https://docs.google.com/spreadsheets/d/1kxHgFqiUB9ETXYEkszAIN5gE-t2ykvnPCnOV-sPUE0A/edit#gid=1167536015&range=B7:AN7
	const uint8_t stateHumidAuto[kDaikin2StateLength] = {
	0x11, 0xDA, 0x27, 0x00, 0x01, 0x00, 0x40, 0x50, 0x60, 0x0C, 0x80, 0x04,
	0xB0, 0x16, 0x24, 0x00, 0x00, 0x8B, 0xCE, 0xD6, 0x11, 0xDA, 0x27, 0x00,
	0x00, 0x49, 0xC0, 0xFF, 0xA0, 0x00, 0x00, 0x06, 0x60, 0x00, 0x00, 0xC1,
	0x90, 0x60, 0xD1};
	ac.stateReset();
	ac.setRaw(stateHumidAuto);
	EXPECT_TRUE(ac._.HumidOn);
	EXPECT_EQ(kDaikinHeat, ac.getMode());
	EXPECT_EQ(kDaikinMaxTemp, ac.getTemp());
	EXPECT_EQ(kDaikin2HumidityAuto, ac.getHumidity());

In short, you neet to use the "getters" (e.g. .getMode()) from the specific AC class object for the message.

You can also look at how .resultToAcString() works. e.g.

IRremoteESP8266/src/IRac.cpp

Lines 4061 to 4073 in 9bdf8ab

	/// Display the human readable state of an A/C message if we can.
	/// @param[in] result A Ptr to the captured `decode_results` that contains an
	/// A/C mesg.
	/// @return A string with the human description of the A/C message.
	/// An empty string if we can't.
	String resultAcToString(const decode_results * const result) {
	switch (result->decode_type) {
	#if DECODE_AIRTON
	case decode_type_t::AIRTON: {
	IRAirtonAc ac(kGpioUnused);
	ac.setRaw(result->value); // AIRTON uses value instead of state.
	return ac.toString();
	}

and add something like the follow after the ac.setRaw() call:

uint16_t mode;
  mode = ac.getMode();

[LionKKK]

Thank you. It helped. Everything works
My code:
`void loop() {
// Check if the IR code has been received.
if (irrecv.decode(&results)) {

  IRGreeAC ac_test(kGpioUnused);
  ac_test.setRaw(results.state);
  Serial.print("Mode: ");
  Serial.println(ac_test.getMode());  // Mode: 1
  Serial.print("FanSpeed: ");
  Serial.println(ac_test.getFan());     // FanSpeed: 2
  Serial.print("Temp: ");
  Serial.println(ac_test.getTemp());  // Temp: 2
  Serial.print("Power: ");
  Serial.println(ac_test.getPower()); // Power: 1

}
}
`