build.gradle

apply plugin: 'java'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
    compile "org.nd4j:nd4j-native-platform:1.0.0-beta3"
    compile group: 'com.github.wendykierp', name: 'JTransforms', version: '3.1'
}

test {
    useJUnit {
        exclude '**/*PerformanceTest.class'
    }
}

task performanceTest(type: Test) {
    useJUnit {
        include '**/*PerformanceTest.class'
    }
}

// Signing
apply plugin: 'signing'
signing {
    sign configurations.archives
}


// Deploying
apply plugin: 'maven'

// Add Javadoc JAR and sources JAR to artifact
task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}
task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}
artifacts {
    archives javadocJar, sourcesJar
}

group = "io.github.ensozos"
archivesBaseName = "matrix-profile"
version '0.0.3'


// Build, sign, and upload
uploadArchives {
    repositories {
        mavenDeployer {

            // Sign POM
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            // Destination
            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }
            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            // Add required metadata to POM
            pom.project {
                name 'Matrix Profile'
                packaging 'jar'
                description 'A Java library that allows you to use the Matrix Profile concept as a toolkit'
                url 'https://github.com/ensozos/Matrix-Profile'

                scm {
                    connection 'scm:git:git://github.com/ensozos/Matrix-Profile.git'
                    developerConnection 'scm:git:ssh://github.com/ensozos/Matrix-Profile.git'
                    url 'http://github.com/ensozos/Matrix-Proifle/tree/master'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id 'ensozos'
                        name 'Zosimadis Ilias'
                        email 'zosimadi@csd.auth.gr'
                        organization 'ensozos'
                        organizationUrl 'https://ensozos.github.io/Matrix-Profile/'
                    }
                }
            }
        }
    }
}