-
Notifications
You must be signed in to change notification settings - Fork 0
/
SRC_PROPAGANDA.WL
4955 lines (4955 loc) · 290 KB
/
SRC_PROPAGANDA.WL
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ################################################################################################################################################################ *)
(* PROPAGANDA, SINGLE PARTICLE NONLINEAR DYNAMICS TOOLKIT, 2017-2023 *)
(* ################################################################################################################################################################ *)
(* INITIALIZATION *)
(* ################################################################################################################################################################ *)
ClearSystemCache[] ; (* -- CLEAR SYSTEM CACHE *)
Set[$HistoryLength,0] ; (* -- NO HISTORY *)
Get["CompiledFunctionTools`"] ; (* -- LOAD COMPILED FUNCTION PACKAGE *)
Get["CCompilerDriver`"] ; (* -- LOAD COMPILER DRIVER PACKAGE *)
Get["MaTeX`"] ; (* -- LOAD MATEX PACKAGE *)
(* ################################################################################################################################################################ *)
(* SYSTEM COMPILE OPTIONS *)
(* ################################################################################################################################################################ *)
Compiler`$CCompilerOptions = List[Rule["SystemCompileOptions","-O3 -ffast-math -march=native"]] ;
(* ################################################################################################################################################################ *)
(* PARALLEL MAP *)
(* ################################################################################################################################################################ *)
ClearAll[I$PARALLEL$MAP] ;
I$PARALLEL$MAP::usage = "
I$PARALLEL$MAP[FUNCTION,LIST] -- (function) apply function <FUNCTION> (function) to list of arguments <LIST> (list) using ParallelMap
" ;
Options[I$PARALLEL$MAP] = List[
Rule["METHOD","FinestGrained"] (* -- METHOD *)
] ;
I$PARALLEL$MAP[ (* -- (CUSTOM) PARALLEL MAP FUNCTION *)
FUNCTION_, (* -- FUNCTION TO APPLY (FUNCTION) *)
LIST_List, (* -- ARGUMENT (LIST) *)
OPTIONS:OptionsPattern[] (* -- OPTION(S) *)
] := Catch[
ParallelMap[FUNCTION,LIST,Rule[Method,OptionValue["METHOD"]]]
] ;
(* ################################################################################################################################################################ *)
(* INSERT ELEMENTS *)
(* ################################################################################################################################################################ *)
ClearAll[I$INSERT] ;
I$INSERT::usage = "
I$INSERT[LIST,DATA,MASK] -- (function) insert a list of elements <DATA> (list) into a list <LIST> (list), inserted elements appear according to a list of positions <MASK> (list of integers)
" ;
I$INSERT[ (* -- INSERT A LIST OF ELEMENTS INTO A LIST SO THAT NEW ELEMENTS APPEAR AT GIVEN POSITIONS IN THE RESULT *)
LIST_List, (* -- INITIAL LIST OF ELEMENTS (LIST) *)
DATA_List, (* -- LIST OF ELEMENTS TO INSERT (LIST) *)
MASK_List (* -- LIST OF POSITIONS FOR INSERTED ELEMENTS (LIST OF INTEGERS) *)
] := Catch[
Block[
{LENGTH,RESULT,RULE},
LENGTH = Plus[Length[LIST],Length[DATA]] ;
RESULT = ConstantArray[0,LENGTH] ;
RULE = Thread[Rule[MASK,DATA]] ;
RESULT = ReplacePart[RESULT,RULE] ;
RULE = Thread[Rule[DeleteCases[Range[LENGTH],Apply[Alternatives,MASK]],LIST]] ;
ReplacePart[RESULT,RULE]
]
] /; And[
Apply[And,Map[IntegerQ,MASK]],
LessEqual[Max[MASK],Plus[Length[LIST],Length[DATA]]],
SameQ[Length[DeleteDuplicates[MASK]],Length[MASK]]
] ;
(* ################################################################################################################################################################ *)
(* INTEGRATOR (MAIN INITIALIZATION) *)
(* ################################################################################################################################################################ *)
ClearAll[I$INTEGRATOR] ;
I$INTEGRATOR::usage =
"
I$INTEGRATOR[DIRECTORY,DIMENSION,CORDER,KNOB,KORDER,MASK] -- (function) initialize integrator using working directory name <DIRECTORY> (string), configuration space dimension <DIMENSION> (integer), total canonical monomial degree <CORDER> (integer), total number of parameters <KNOB> (integer), total combined parameters monomial order <KORDER> (integer) and list of individual maximum orders for each parameter <MASK> (list of integers or empty list)
I$INTEGRATOR[DIRECTORY,DIMENSION] -- (function) initialize integrator using working directory <DIRECTORY> (string) and configuration space dimension <DIMENSION> (integer)
I$INTEGRATOR[DIRECTORY,DIMENSION,CORDER] -- (function) initialize integrator using working directory <DIRECTORY> (string), configuration space dimension <DIMENSION> (integer) and total canonical monomial order <CORDER> (integer)
" ;
Options[I$INTEGRATOR] = List[
Rule["FLAG",W], (* -- APERTURE FLAG (SYMBOL) *)
Rule["PARAMETER",S], (* -- FORMAL INTEGRATION PARAMETER (SYMBOL) *)
Rule["ORDERING","PAIRS"], (* -- CANONICAL COORDINATES ORDERING ("PAIRS" (DEFAULT) OR "SECTORS") *)
Rule["QHEAD","Q"], (* -- HEAD FOR CANONICAL Q-VARIABLES (STRING) *)
Rule["PHEAD","P"], (* -- HEAD FOR CANONICAL P-VARIABLES (STRING) *)
Rule["KHEAD","K"], (* -- HEAD FOR PARAMETER VARIABLES (STRING) *)
Rule["DHEAD","D"], (* -- HEAD FOR DERIVATIVE VARIABLES (STRING) *)
Rule["FHEAD","F"], (* -- HEAD FOR PARAMETERS FLAGS (STRING) *)
Rule["FILTER",Identity], (* -- COMPONENTS FILTER FUNCTION (FUNCTION) (ACTS ON LIST OF ALL COMPONENTS) *)
Rule["TRUNCATION","SUM"], (* -- TRUNCATION TYPE ("SUM" (DEFAULT) OR "MAX"), "SUM" COMBINES CANONICAL AND PARAMETRIC ORDERS, "MAX" USES THEIR MAXIMUM *)
Rule["VERBOSE",False] (* -- VERBOSE FLAG (LOGICAL), PRINT INFO *)
] ;
I$INTEGRATOR[ (* -- INITIALIZE INTEGRATOR *)
DIRECTORY_String, (* -- DIRECTORY NAME (STRING) *)
DIMENSION_Integer, (* -- CONFIGURATION SPACE DIMENSION (INTEGER) *)
CORDER_Integer, (* -- MAXIMUM TOTAL MONOMIAL DEGREE FOR CANONICAL VARIABLES (INTEGER) *)
KNOB_Integer, (* -- TOTAL NUMBER OF (DEVIATION) PARAMETERS (INTEGER) *)
KORDER_Integer, (* -- MAXIMUM TOTAL MONOMIAL DEGREE FOR PARAMETERS (INTEGER) *)
MASK_List, (* -- LIST OF MAXIMUM INDIVIDUAL ORDERS FOR EACH PARAMETER (LIST OF INTEGERS OR EMPTY LIST) *)
OPTIONS:OptionsPattern[] (* -- OPTION(S) *)
] := Catch[
Block[
{VERBOSE},
(* SET VERBOSE FLAG *)
VERBOSE = OptionValue["VERBOSE"] ;
(* SET AND/OR CREATE WORKING DIRECTORY *)
SetDirectory[NotebookDirectory[]] ;
I$DIRECTORY = FileNameJoin[List[NotebookDirectory[],DIRECTORY]] ;
If[Not[DirectoryQ[I$DIRECTORY]],CreateDirectory[I$DIRECTORY]] ;
SetDirectory[I$DIRECTORY] ;
(* SET INTEGRATOR SIGNATURE (LIST OF INPUT ARGUMENTS) *)
I$SIGNATURE = List[DIRECTORY,DIMENSION,CORDER,KNOB,KORDER,MASK] ;
If[VERBOSE,Print["INTEGRATOR INITIALIZATION"]] ;
If[VERBOSE,Print[StringTemplate["SIGNATURE : ``"][I$SIGNATURE]]] ;
(* SET APERTURE FLAG (SYMBOL) *)
I$FLAG = OptionValue["FLAG"] ;
If[UnsameQ[Head[I$FLAG],Symbol],Throw[$Failed]] ;
If[VERBOSE,Print[StringTemplate["APERTURE FLAG : ``"][I$FLAG]]] ;
(* SET FORMAL INTEGRATION PARAMETER (SYMBOL) *)
I$PARAMETER = OptionValue["PARAMETER"] ;
If[UnsameQ[Head[I$PARAMETER],Symbol],Throw[$Failed]] ;
If[VERBOSE,Print[StringTemplate["INTEGRATION PARAMETER : ``"][I$PARAMETER]]] ;
(* SET CANONICAL COORDINATES ORDERING (STRING) *)
I$ORDERING = OptionValue["ORDERING"] ;
If[Not[MemberQ[List["PAIRS","SECTORS"],I$ORDERING]],Throw[$Failed]] ;
If[VERBOSE,Print[StringTemplate["PHASE SPACE ORDERING : ``"][I$ORDERING]]] ;
(* SET VARIABLE HEADS (LIST OF STRINGS) *)
List[I$Q$HEAD,I$P$HEAD,I$K$HEAD,I$D$HEAD,I$F$HEAD] = List[OptionValue["QHEAD"],OptionValue["PHEAD"],OptionValue["KHEAD"],OptionValue["DHEAD"],OptionValue["FHEAD"]] ;
If[Not[AllTrue[List[I$Q$HEAD,I$P$HEAD,I$K$HEAD,I$D$HEAD,I$F$HEAD],StringQ]],Throw[$Failed]] ;
If[VERBOSE,Print[StringTemplate["VARIABLE HEADS : ``"][List[I$Q$HEAD,I$P$HEAD,I$K$HEAD,I$D$HEAD,I$F$HEAD]]]] ;
(* SET CONFIGURATION SPACE DIMENSION (INTEGER) *)
I$DIMENSION = DIMENSION ;
If[VERBOSE,Print[StringTemplate["DIMENSION : ``"][I$DIMENSION]]] ;
(* SET CANONICAL SPACE DIMENSION (INTEGER) *)
I$DIMENSION$CANONICAL = Times[Plus[1,1],I$DIMENSION] ;
If[VERBOSE,Print[StringTemplate["CANONICAL DIMENSION : ``"][I$DIMENSION$CANONICAL]]] ;
(* SET CANONICAL VARIABLES (LIST OF SYMBOLS ACCORDING TO SELECTED ORDERING) *)
I$VARIABLES$CANONICAL = Composition[
ToExpression,
Function[Which[SameQ[I$ORDERING,"PAIRS"],Flatten[Slot[1]],SameQ[I$ORDERING,"SECTORS"],Flatten[Transpose[Slot[1]]]]],
Function[Array[Function[Through[List[StringTemplate[StringJoin[I$Q$HEAD,"``"]],StringTemplate[StringJoin[I$P$HEAD,"``"]]][Slot[1]]]],Slot[1]]]
][I$DIMENSION] ;
If[VERBOSE,Print[StringTemplate["CANONICAL VARIABLES : ``"][I$VARIABLES$CANONICAL]]] ;
(* SET CANONICAL Q & P-VARIABLES (LIST OF SYMBOLS) *)
I$VARIABLES$CANONICAL$Q = Select[I$VARIABLES$CANONICAL,Function[SameQ[StringTake[ToString[Slot[1]],1],I$Q$HEAD]]] ;
I$VARIABLES$CANONICAL$P = Select[I$VARIABLES$CANONICAL,Function[SameQ[StringTake[ToString[Slot[1]],1],I$P$HEAD]]] ;
(* SET PLANES *)
ClearAll[I$PLANE] ;
Apply[Set,List[Array[I$PLANE,I$DIMENSION],Transpose[List[I$VARIABLES$CANONICAL$Q,I$VARIABLES$CANONICAL$P]]]] ;
(* SET SYMPLECTIC MATRIX FOR GIVEN CANONICAL DIMENSION AND CANONICAL COORDINATES ORDERING (MATRIX) *)
I$SYMPLECTIC$MATRIX = Which[
SameQ[I$ORDERING,"PAIRS"],
ArrayFlatten[Outer[Times,IdentityMatrix[I$DIMENSION],List[List[0,1],List[Subtract[0,1],0]]]],
SameQ[I$ORDERING,"SECTORS"],
Join[PadLeft[IdentityMatrix[I$DIMENSION],List[I$DIMENSION,I$DIMENSION$CANONICAL]],PadRight[Subtract[0,IdentityMatrix[I$DIMENSION]],List[I$DIMENSION,I$DIMENSION$CANONICAL]]]
] ;
(* SET PARAMETER SPACE DIMENSION/NUMBER OF PARAMETERS (INTEGER) *)
I$DIMENSION$PARAMETRIC = KNOB ;
If[VERBOSE,Print[StringTemplate["PARAMETRIC DIMENSION : ``"][I$DIMENSION$PARAMETRIC]]] ;
(* SET PARAMETETRIC VARIABLES (LIST OF SYMBOLS) *)
I$VARIABLES$PARAMETRIC = ToExpression[Map[Function[StringJoin[I$K$HEAD,ToString[Slot[1]]]],Range[I$DIMENSION$PARAMETRIC]]] ;
If[VERBOSE,Print[StringTemplate["PARAMETRIC VARIABLES : ``"][I$VARIABLES$PARAMETRIC]]] ;
(* SET FLAGS FOR PARAMETERS (USED TO GENERATE SEVERAL ELEMENTS FROM A SINGLE DEFINITION) *)
I$FLAG$PARAMETRIC = ToExpression[Map[Function[StringJoin[I$F$HEAD,ToString[Slot[1]]]],Range[I$DIMENSION$PARAMETRIC]]] ;
If[VERBOSE,Print[StringTemplate["PARAMETRIC FLAGS : ``"][I$FLAG$PARAMETRIC]]] ;
(* FLAG RULES *)
I$RULE$PARAMETRIC = Dispatch[Thread[Rule[I$VARIABLES$PARAMETRIC,Times[I$FLAG$PARAMETRIC,I$VARIABLES$PARAMETRIC]]]] ;
(* SET LIST OF ORDERS FOR CANONICAL VARIABLES AND PARAMETERS (LIST OF INTEGERS) *)
I$ORDER$LIST = Join[
ConstantArray[CORDER,I$DIMENSION$CANONICAL],
If[SameQ[MASK,List[]],ConstantArray[KORDER,I$DIMENSION$PARAMETRIC],Map[Min,Transpose[List[ConstantArray[KORDER,I$DIMENSION$PARAMETRIC],MASK]]]]
] ;
If[VERBOSE,Print[StringTemplate["LIST OF ORDERS : ``"][Thread[Rule[Flatten[List[I$VARIABLES$CANONICAL,I$VARIABLES$PARAMETRIC]],I$ORDER$LIST]]]]] ;
(* SET MAXIMUM ORDER OF GENERIC MONOMIAL (CANONICAL VARIABLES AND PARAMETERS) (INTEGER) *)
If[Not[MemberQ[List["SUM","MAX"],OptionValue["TRUNCATION"]]],Throw[$Failed]] ;
I$ORDER = Which[
SameQ[OptionValue["TRUNCATION"],"SUM"],
Plus[CORDER,KORDER],
SameQ[OptionValue["TRUNCATION"],"MAX"],
Max[List[CORDER,KORDER]]
] ;
I$ORDER$CANONICAL = CORDER ;
I$ORDER$PARAMETRIC = KORDER ;
If[VERBOSE,Print[StringTemplate["TRUNCATION : ``"][OptionValue["TRUNCATION"]]]] ;
If[VERBOSE,Print[StringTemplate["GENERIC ORDER : ``"][I$ORDER]]] ;
(* SET DEVIATION VARIABLES DIMENSION (NUMBER OF CANONICAL VARIABLES AND PARAMETERS WITH NONZERO ORDERS) (INTEGER) *)
I$DIMENSION$DEVIATION = Length[DeleteCases[I$ORDER$LIST,0]] ;
If[VERBOSE,Print[StringTemplate["DEVIATION DIMENSION : ``"][I$DIMENSION$DEVIATION]]] ;
(* SET DEVIATION VARIABLES (CANONICAL VARIABLES AND PARAMETERS WITH NONZERO ORDERS) (LIST OF SYMBOLS) *)
I$VARIABLES$DEVIATION = Pick[Flatten[List[I$VARIABLES$CANONICAL,I$VARIABLES$PARAMETRIC]],Unitize[I$ORDER$LIST],1] ;
If[VERBOSE,Print[StringTemplate["DEVIATION VARIABLES : ``"][I$VARIABLES$DEVIATION]]] ;
(* SET ALL POSSIBLE DERIVATIVES OF CANONICAL VARIABLES WITH RESPECT TO DEVIATION VARIABLES UP TO MAXIMUM ORDER <ORDER> (INTEGER) OF GENERIC MONOMIAL *)
I$COMPONENTS = Flatten[Map[Composition[Reverse,Function[FrobeniusSolve[ConstantArray[1,I$DIMENSION$DEVIATION],Slot[1]]]],Range[I$ORDER]],1] ;
(* FILTER DERIVATIVES BY CANONICAL VARIABLES (TOTAL CANONICAL MONOMIAL ORDER IS LESS OR EQUAL TO GIVEN CANONICAL ORDER) *)
I$COMPONENTS = If[UnsameQ[I$ORDER$CANONICAL,0],Select[I$COMPONENTS,Function[LessEqual[Total[Take[Slot[1],I$DIMENSION$CANONICAL]],I$ORDER$CANONICAL]]],I$COMPONENTS] ;
(* FILTER DERIVATIVES BY PARAMETERS (TOTAL PARAMETRIC MONOMIAL ORDER IS LESS OR EQUAL TO GIVEN ORDER) *)
I$COMPONENTS = If[And[UnsameQ[I$ORDER$CANONICAL,0],UnsameQ[I$ORDER$PARAMETRIC,0]],Select[I$COMPONENTS,Function[LessEqual[Total[Take[Slot[1],Subtract[0,I$DIMENSION$PARAMETRIC]]],I$ORDER$PARAMETRIC]]],I$COMPONENTS] ;
(* FILTER DERIVATIVES BY PARAMETERS (INDIVIDUAL LIST, PAR_I^POW_J IS REMOVED IF POW_J IS GREATER OR EQUAL TO GIVEN ORDER OF PAR_I) *)
I$COMPONENTS = Select[I$COMPONENTS,Function[Apply[And,Thread[LessEqual[Slot[1],DeleteCases[I$ORDER$LIST,0]]]]]] ;
(* APPLY FILTER *)
If[Not[MemberQ[List[Symbol,Function],Head[OptionValue["FILTER"]]]],Throw[$Failed]] ;
I$COMPONENTS = OptionValue["FILTER"][I$COMPONENTS] ;
(* ADD COMPONENT INDEX (CANONICAL COMPONENT MARKER) TO SELECTED DERIVATIVES *)
(* COMPONENTS STRUCTURE: {{C_1,D_1},...,{C_N,D_1},{C_1,D_2},...,{C_N,D_2},...,{C_1,D_M},...,{C_N,D_M}} *)
I$COMPONENTS = Flatten[Transpose[Outer[Composition[Flatten,List],Range[I$DIMENSION$CANONICAL],I$COMPONENTS,1]],1] ;
(* SET LENGTH OF COMPONENTS (GROUPED BY GENERIC MONOMICAL ORDER) *)
I$COMPONENTS$LENGTH = Map[Length,GatherBy[I$COMPONENTS,Composition[Total,Rest]]] ;
If[VERBOSE,Print[StringTemplate["FILTER : ``"][UnsameQ[Identity,OptionValue["FILTER"]]]]] ;
If[VERBOSE,Print[StringTemplate["NUMBER OF COMPONENTS : ``"][I$COMPONENTS$LENGTH]]] ;
(* SET DERIVATIVE VARIABLES (DERIVATIVES OF CANONICAL VARIABLES WITH RESPECT TO DEVIATION VARIABLES) (LIST OF SYMBOLS) *)
(* E.G. D$X$A$B$... -- DERIVATIVE OF X COMPONENT WITH RESPECT TO 1ST DEVIATION VARIABLE 'A' TIMES, 2ND DEVIATION VARIABLE 'B' TIMES, ... *)
I$VARIABLES$DERIVATIVE = ToExpression[Map[Composition[Function[StringJoin[I$D$HEAD,"$",Slot[1]]],Function[StringRiffle[Slot[1],"$"]],Map[ToString]],I$COMPONENTS]] ;
(* SET DIMENSION OF DERIVATIVE SPACE (INTEGER) *)
I$DIMENSION$DERIVATIVE = Length[I$VARIABLES$DERIVATIVE] ;
If[VERBOSE,Print[StringTemplate["DERIVATIVE DIMENSION : ``"][I$DIMENSION$DERIVATIVE]]] ;
(* SET ASTATE VARIABLES (FLAG, PARAMETERS, CANONICAL VARIABLES AND DERIVATIVES OF CANONICAL VARIABLES WITH RESPECT TO DEVIATION VARIABLES) (LIST OF SYMBOLS) *)
I$VARIABLES = Flatten[List[I$FLAG,I$VARIABLES$PARAMETRIC,I$VARIABLES$CANONICAL,I$VARIABLES$DERIVATIVE]] ;
(* SET STATE DIMENSION (INTEGER) *)
I$DIMENSION$VARIABLES = Length[I$VARIABLES] ;
If[VERBOSE,Print[StringTemplate["STATE DIMENSION : ``"][I$DIMENSION$VARIABLES]]] ;
(* SET VARIABLES FOR COMPUTATION OF COMPONENTS REPLACEMENT RULES AND DEFINE REPLACMENT RULES *)
(* USED TO REPLACE CANONICAL VARIABLES AND PARAMETERS IN GIVEN VECTOR FIELD OR MAP BY GENERIC VARIABLES *)
ClearAll[I$GP] ;
ClearAll[I$GV] ;
ClearAll[I$GENERIC$PAR$LIST] ;
ClearAll[I$GENERIC$VAR$LIST] ;
I$GENERIC$PAR$LIST = Array[I$GP,I$DIMENSION$DEVIATION] ;
I$GENERIC$VAR$LIST = Array[I$GV,I$DIMENSION$CANONICAL] ;
I$GENERIC$VAR$LIST = Flatten[Outer[Apply,I$GENERIC$VAR$LIST,List[I$GENERIC$PAR$LIST],1]] ;
I$RULE$COMPONENTS = Transpose[List[I$VARIABLES$DEVIATION,I$GENERIC$PAR$LIST]] ;
I$RULE$COMPONENTS = Select[I$RULE$COMPONENTS,Composition[Function[MemberQ[Slot[1]][I$VARIABLES$PARAMETRIC]],First]] ;
I$RULE$COMPONENTS = Join[Transpose[List[I$VARIABLES$CANONICAL,I$GENERIC$VAR$LIST]],I$RULE$COMPONENTS] ;
I$RULE$COMPONENTS = Dispatch[Map[Apply[Rule],I$RULE$COMPONENTS]] ;
(* SET VARIABLES FOR COMPUTATION OF DERIVATIVE REPLACEMENT RULES AND DEFINE RULES *)
(* DEFINES CORRESPONDENCE OF GENERIC DEVIVATIVES AND DEVIVATIVE VARIABLES *)
I$GENERIC$PAR$LIST = Array[I$GP,I$DIMENSION$DEVIATION] ;
I$GENERIC$VAR$LIST = Array[I$GV,I$DIMENSION$CANONICAL] ;
I$GENERIC$VAR$LIST = Flatten[Outer[Apply,I$GENERIC$VAR$LIST,List[I$GENERIC$PAR$LIST],1]] ;
I$RULE$DERIVATIVE = Map[Function[Operate[Apply[Derivative,Rest[Slot[1]]],Part[I$GENERIC$VAR$LIST,First[Slot[1]]]]],I$COMPONENTS] ;
I$RULE$DERIVATIVE = Dispatch[Thread[Rule[I$RULE$DERIVATIVE,I$VARIABLES$DERIVATIVE]]] ;
ClearAll[I$GENERIC$PAR$LIST] ;
ClearAll[I$GENERIC$VAR$LIST] ;
(* COMPONENTS FUNCTION BUILDER FROM VECTOR OF DERIVATIVES (NO CONSTANT COMPONENT, ACTS ON A LIST OF DERIVATIVES, RETURNS LIST GROUPED BY TOTAL GENERIC MONOMIAL ORDER) *)
ClearAll[I$MAKE$FUNCTIONS] ;
I$MAKE$FUNCTIONS = Values[GroupBy[I$COMPONENTS,First]] ;
I$MAKE$FUNCTIONS = Map[
Function[
Block[
{COMPONENT,INDEX,FACTOR,EXPRESSION,LIST},
COMPONENT = ToString[Part[Slot[1],1,1]] ;
INDEX = SplitBy[Map[Rest,Slot[1]],Total] ;
FACTOR = Map[Map[Apply[Multinomial]],INDEX] ;
EXPRESSION = Map[Map[Function[Apply[Times,Power[I$VARIABLES$DEVIATION,Slot[1]]]]],INDEX] ;
EXPRESSION = Times[FACTOR,EXPRESSION] ;
LIST = ToExpression[Apply[Composition[Function[StringJoin[I$D$HEAD,"$",COMPONENT,"$",Slot[1]]],Function[StringRiffle[Slot[1],"$"]],Map[ToString],List],INDEX,List[2]]] ;
N[Expand[Times[Divide[1,Factorial[Range[Length[LIST]]]],MapThread[Dot,List[LIST,EXPRESSION]]]]]
]
],
I$MAKE$FUNCTIONS
] ;
I$MAKE$FUNCTIONS = Apply[Function,List[I$VARIABLES$DERIVATIVE,I$MAKE$FUNCTIONS]] ;
I$MAKE$FUNCTIONS = Apply[I$MAKE$FUNCTIONS] ;
(* SET DSOLVE VARIABLES (ONLY CANONICAL VARIABLES) (LIST OF SYMBOLS) *)
I$DSOLVE$VARIABLES = I$VARIABLES$CANONICAL ;
(* SET DSOLVE PARAMETERS (GENERIC INITIAL VALUES FOR DSOLVE VARIABLES) (LIST OF SYMBOLS) *)
I$DSOLVE$PARAMETERS = Flatten[ToExpression[Outer[StringJoin,Map[ToString,I$DSOLVE$VARIABLES],List["$"]]]] ;
(* SET DSOLVE EQUATIONS FOR INITIALS *)
I$DSOLVE$INITIALS = Thread[Equal[Through[I$DSOLVE$VARIABLES[0]],I$DSOLVE$PARAMETERS]] ;
(* SET DSOLVE RULE (REPLACE GENERIC INITIAL VALUES WITH CANONICAL VARIABLES) *)
I$DSOLVE$RULE = Dispatch[Thread[Rule[I$DSOLVE$PARAMETERS,I$DSOLVE$VARIABLES]]] ;
(* SET NDSOLVE VARIABLES (CANONICAL VARIABLES AND DERIVATIVES) *)
I$NDSOLVE$VARIABLES = Flatten[List[I$VARIABLES$CANONICAL,I$VARIABLES$DERIVATIVE]] ;
(* SET NDSOLVE PARAMETERS (GENERIC INITIAL VALUES FOR NDSOLVE VARIABLES) *)
I$NDSOLVE$PARAMETERS = Flatten[ToExpression[Outer[StringJoin,Map[ToString,I$NDSOLVE$VARIABLES],List["$"]]]] ;
(* SET NDSOLVE INITIALS *)
I$NDSOLVE$INITIALS = Thread[Equal[Through[I$NDSOLVE$VARIABLES[0]],I$NDSOLVE$PARAMETERS]] ;
(* ADD PARAMETRIC VARIABLES TO NDSOLVE PARAMETERS *)
I$NDSOLVE$PARAMETERS = Join[I$VARIABLES$PARAMETRIC,I$NDSOLVE$PARAMETERS] ;
(* CLEAN GLOBAL CODE VARIABLES AND ATTRIBUTES *)
SetAttributes[I$GP,NHoldAll] ;
SetAttributes[I$GV,NHoldAll] ;
ClearAll[I$STATE] ;
ClearAll[I$GLOBAL] ;
ClearAll[I$LOCAL] ;
SetAttributes[I$STATE,NHoldAll] ;
SetAttributes[I$LOCAL,NHoldAll] ;
SetAttributes[I$GLOBAL,NHoldAll] ;
(* CLEAN GLOBAL CODE FUNCTIONS AND SET ATTRIBUTES *)
ClearAll[I$BLOCK] ;
ClearAll[I$COMPOUND$EXPRESSION] ;
ClearAll[I$SEQUENCE] ;
ClearAll[I$SET] ;
ClearAll[I$PLUS] ;
ClearAll[I$TIMES] ;
ClearAll[I$DIVIDE] ;
ClearAll[I$POWER] ;
ClearAll[I$EXP] ;
ClearAll[I$SIN] ;
ClearAll[I$COS] ;
ClearAll[I$TAN] ;
ClearAll[I$COT] ;
ClearAll[I$ARCSIN] ;
ClearAll[I$ARCCOS] ;
ClearAll[I$ARCTAN] ;
ClearAll[I$ARCCOT] ;
ClearAll[I$SINH] ;
ClearAll[I$COSH] ;
ClearAll[I$MATH$E] ;
ClearAll[I$MATH$PI] ;
ClearAll[I$IF] ;
ClearAll[I$DO] ;
ClearAll[I$GREATER] ;
ClearAll[I$LESS] ;
ClearAll[I$GREATER$EQUAL] ;
ClearAll[I$LESS$EQUAL] ;
ClearAll[I$EQUAL] ;
ClearAll[I$LIST] ;
ClearAll[I$THROW] ;
ClearAll[I$CATCH] ;
ClearAll[I$COMPILE] ;
ClearAll[I$SQRT] ;
ClearAll[I$PART] ;
ClearAll[I$LOG] ;
ClearAll[I$LOG10] ;
SetAttributes[I$POWER,NHoldRest] ;
(* CODE REPLACEMENT RULES (REPLACE VARIABLES WITH CODE STATE) *)
I$RULE$STATE = Dispatch[Thread[Rule[I$VARIABLES,Array[I$STATE,I$DIMENSION$VARIABLES]]]] ;
(* RETURN SIGNATURE (INPUT ARGUMENTS) *)
I$SIGNATURE
]
] /; And[
GreaterEqual[DIMENSION,0],
GreaterEqual[KNOB,0],
GreaterEqual[CORDER,0],
GreaterEqual[KORDER,0]
] ;
(* ABBREVIATION(S) *)
I$INTEGRATOR[DIRECTORY_String,DIMENSION_Integer,OPTIONS:OptionsPattern[]] := I$INTEGRATOR[DIRECTORY,DIMENSION,0,0,0,List[],OPTIONS] ;
I$INTEGRATOR[DIRECTORY_String,DIMENSION_Integer,CORDER_Integer,OPTIONS:OptionsPattern[]] := I$INTEGRATOR[DIRECTORY,DIMENSION,CORDER,0,0,List[],OPTIONS] ;
(* GLOBAL VARIABLES AND FUNCTIONS DEFINED BY I$INTEGRATOR[] *)
I$SIGNATURE::usage = "I$SIGNATURE -- (variable) integrator signature (list of input arguments for I$INTEGRATOR) " ;
I$DIRECTORY::usage = "I$DIRECTORY -- (variable) working directory (path) " ;
I$FLAG::usage = "I$FLAG -- (variable) aperture flag parameter (symbol) " ;
I$PARAMETER::usage = "I$PARAMETER -- (variable) integration parameter (symbol) " ;
I$ORDERING::usage = "I$ORDERING -- (variable) canonical space ordering (string) " ;
I$Q$HEAD::usage = "I$Q$HEAD -- (variable) canonical q-coordinates head (string) " ;
I$P$HEAD::usage = "I$P$HEAD -- (variable) canonical p-coordinates head (string) " ;
I$K$HEAD::usage = "I$K$HEAD -- (variable) parameter head (string) " ;
I$D$HEAD::usage = "I$D$HEAD -- (variable) derivative head (string) " ;
I$F$HEAD::usage = "I$F$HEAD -- (variable) parameter flag head (string) " ;
I$DIMENSION::usage = "I$DIMENSION -- (variable) configuration space dimension (integer) " ;
I$DIMENSION$CANONICAL::usage = "I$DIMENSION$CANONICAL -- (variable) canonical space dimension (integer) " ;
I$VARIABLES$CANONICAL::usage = "I$VARIABLES$CANONICAL -- (variable) list of canonical variables (list of symbols) " ;
I$VARIABLES$CANONICAL$Q::usage = "I$VARIABLES$CANONICAL$Q -- (variable) list of canonical q-variables (list of symbols) " ;
I$VARIABLES$CANONICAL$P::usage = "I$VARIABLES$CANONICAL$P -- (variable) list of canonical p-variables (list of symbols) " ;
I$PLANE::usage = "I$PLANE[INDEX] -- canonical pair corresponding to <INDEX> (integer) plane " ;
I$SYMPLECTIC$MATRIX::usage = "I$SYMPLECTIC$MATRIX -- (variable) symplectic matrix " ;
I$DIMENSION$PARAMETRIC::usage = "I$DIMENSION$PARAMETRIC -- (variable) parametric dimension (integer) " ;
I$VARIABLES$PARAMETRIC::usage = "I$VARIABLES$PARAMETRIC -- (variable) parametric variables (list of symbols) " ;
I$FLAG$PARAMETRIC::usage = "I$FLAG$PARAMETRIC -- (variable) parametric flag variables (list of symbols) " ;
I$RULE$PARAMETRIC::usage = "I$RULE$PARAMETRIC -- (rule) parametric rules (rules) " ;
I$ORDER$LIST::usage = "I$ORDER$LIST -- (variable) list of orders for all deviation variables (list of integers) " ;
I$ORDER::usage = "I$ORDER -- (variable) maximum generic monomial order (integer) " ;
I$DIMENSION$DEVIATION::usage = "I$DIMENSION$DEVIATION -- (variable) deviation space dimension (integer) " ;
I$VARIABLES$DEVIATION::usage = "I$VARIABLES$DEVIATION -- (variable) list of deviation variables (list of symbols) " ;
I$COMPONENTS::usage = "I$COMPONENTS -- (variable) selected derivative components (list) " ;
I$COMPONENTS$LENGTH::usage = "I$COMPONENTS$LENGTH -- (variable) length of selected derivative components grouped by generic order (list of integers) " ;
I$VARIABLES$DERIVATIVE::usage = "I$VARIABLES$DERIVATIVE -- (variable) list of derivative variables (list of symbols) " ;
I$DIMENSION$DERIVATIVE::usage = "I$DIMENSION$DERIVATIVE -- (variable)derivative space dimension (integer) " ;
I$RULE$COMPONENTS::usage = "I$RULE$COMPONENTS -- (rule) generic rules for components (rules) " ;
I$RULE$DERIVATIVE::usage = "I$RULE$DERIVATIVE -- (rule) generic rules for derivaties (rules) ";
I$MAKE$FUNCTIONS::usage = "I$MAKE$FUNCTIONS -- (function) components function builder (function) " ;
I$VARIABLES::usage = "I$VARIABLES -- (variable) state variables (list of symbols) " ;
I$DIMENSION$VARIABLES::usage = "I$DIMENSION$VARIABLES -- (variable) state dimension (integer) " ;
I$DSOLVE$VARIABLES::usage = "I$DSOLVE$VARIABLES -- (variable) dsolve variables " ;
I$DSOLVE$PARAMETERS::usage = "I$DSOLVE$PARAMETERS -- (variable) dsolve parameters " ;
I$DSOLVE$INITIALS::usage = "I$DSOLVE$INITIALS -- (variable) dsolve initials " ;
I$DSOLVE$RULE::usage = "I$DSOLVE$RULE -- (rule) dsolve rules " ;
I$NDSOLVE$VARIABLES::usage = "I$NDSOLVE$VARIABLES -- (variable) ndsolve variables " ;
I$NDSOLVE$PARAMETERS::usage = "I$NDSOLVE$PARAMETERS -- (variable) ndsolve parameters " ;
I$NDSOLVE$INITIALS::usage = "I$NDSOLVE$INITIALS -- (variable) ndsolve initials " ;
I$RULE$STATE::usage = "I$RULE$STATE -- (rule) replacement rules for code generation " ;
(* ################################################################################################################################################################ *)
(* MONOMIAL EXPANSION *)
(* ################################################################################################################################################################ *)
ClearAll[I$EXPAND]
I$EXPAND::usage = "
I$EXPAND[DEGREE,VARIABLE,EXPRESSION] -- (function) expand expression <EXPRESSION> near zero with respect to list of monomial variables <VARIABLE> (list of symbols) up to total monomial degree <DEGREE> (integer)
I$EXPAND[EXPRESSION] -- (function) expand expression <EXPRESSION> near zero using current integrator signature)
" ;
I$EXPAND[ (* -- (SERIES) EXPAND EXPRESSION *)
DEGREE_Integer, (* -- TOTAL MONOMIAL DEGREE (INTEGER) *)
VARIABLE_List, (* -- EXPANSION VARIABLES (LIST OF SYMBOLS) *)
EXPRESSION_ (* -- EXPRESSION TO EXPAND *)
] := Catch[
Block[
{PARAMETER,RULE},
RULE = Dispatch[Thread[Rule[VARIABLE,Times[PARAMETER,VARIABLE]]]] ;
ReplaceAll[Normal[Series[ReplaceAll[EXPRESSION,RULE],List[PARAMETER,0,DEGREE]]],Rule[PARAMETER,1]]
]
] /; And[
GreaterEqual[DEGREE,0],
SameQ[DeleteCases[Map[Head,VARIABLE],Symbol],List[]]
] ;
I$EXPAND[List[DEGREE_Integer,VARIABLE_Symbol],EXPRESSION_] := I$EXPAND[DEGREE,List[VARIABLE],EXPRESSION] ;
I$EXPAND[ (* -- (SERIES) EXPAND EXPRESSION ACCORDING TO INTEGRATOR SIGNATURE *)
EXPRESSION_ (* -- EXPRESSION TO EXPAND *)
] := Block[
{SERIES, LIST},
SERIES = I$EXPAND[I$ORDER,I$VARIABLES$CANONICAL,EXPRESSION] ;
SERIES = I$EXPAND[I$ORDER,I$VARIABLES$DEVIATION,EXPRESSION] ;
If[
UnsameQ[List[],Intersection[I$VARIABLES$DEVIATION,I$VARIABLES$CANONICAL]],
SERIES = I$EXPAND[I$ORDER$CANONICAL,I$VARIABLES$CANONICAL,SERIES] ;
] ;
If[
UnsameQ[List[],Intersection[I$VARIABLES$DEVIATION,I$VARIABLES$PARAMETRIC]],
LIST = DeleteCases[Transpose[List[I$ORDER$LIST,I$VARIABLES$DEVIATION]],List[_,X_]/; MemberQ[I$VARIABLES$CANONICAL,X]] ;
SERIES = I$EXPAND[I$ORDER$PARAMETRIC,Last[Transpose[LIST]],SERIES] ;
SERIES = Fold[Composition[Apply[I$EXPAND],Reverse,List],SERIES,LIST] ;
] ;
Collect[SERIES,I$VARIABLES$CANONICAL]
] ;
(* ################################################################################################################################################################ *)
(* COMPOSE CANONICAL MAPS *)
(* ################################################################################################################################################################ *)
ClearAll[I$COMPOSE] ;
Options[I$COMPOSE] = List[
Rule["LINEAR",True], (* -- LINEAR FLAG (IF 'True' ALL MAPS ARE ASSUMED TO BE LINEAR) *)
Rule["DEGREE",1], (* -- EXPANSION DEGREE FOR NONLINEAR CASE (USE NEGATIVE ONE IF NO EXPANSION IS REQUIRED) *)
Rule["SIMPLIFY",Identity] (* -- SIMPLIFICATION FUNCTION *)
] ;
I$COMPOSE::usage = "
I$COMPOSE[LIST] -- compose list of canonical maps <LIST> (list)
" ;
I$COMPOSE[ (* -- COMPOSE LIST OF CANONICAL MAPS *)
LIST_List, (* -- LIST OF CANONICAL MAPS TO COMPOSE *)
OPTIONS:OptionsPattern[] (* -- OPTION(S) *)
] := Catch[
Block[
{MATRIX,MAP,RESULT,LOOP},
If[
OptionValue["LINEAR"],
MATRIX = D[LIST,List[I$VARIABLES$CANONICAL]] ;
MATRIX = Reverse[MATRIX] ;
MATRIX = Apply[Dot,MATRIX] ;
RESULT = Dot[MATRIX,I$VARIABLES$CANONICAL] ;
Throw[RESULT]
] ;
MAP = LIST ;
MAP = Map[Apply[Function],Transpose[List[ConstantArray[I$VARIABLES$CANONICAL,Length[MAP]],MAP]]] ;
RESULT = I$VARIABLES$CANONICAL ;
Do[
List[
RESULT = Apply[Part[MAP,LOOP],RESULT] ;
If[
UnsameQ[OptionValue["DEGREE"],Subtract[0,1]],
RESULT = I$EXPAND[OptionValue["DEGREE"],I$VARIABLES$CANONICAL,RESULT] ;
] ;
RESULT = OptionValue["SIMPLIFY"][RESULT] ;
],
List[LOOP,1,Length[LIST]]
] ;
RESULT
]
] /; Apply[And,Thread[Equal[Map[Length,LIST],I$DIMENSION$CANONICAL]]] ;
(* ################################################################################################################################################################ *)
(* SYMPLECTIC TEST (MATRIX) *)
(* ################################################################################################################################################################ *)
ClearAll[I$SYMPLECTIC$MATRIX$Q] ;
I$SYMPLECTIC$MATRIX$Q::usage = "
I$SYMPLECTIC$MATRIX$Q[MATRIX] -- (function) test symplectic condition for given matrix <MATRIX>
" ;
I$SYMPLECTIC$MATRIX$Q[MATRIX_?SquareMatrixQ] := SameQ[Chop[Map[Simplify,Flatten[Subtract[Dot[Transpose[MATRIX],I$SYMPLECTIC$MATRIX,MATRIX],I$SYMPLECTIC$MATRIX]]]],ConstantArray[0,I$DIMENSION$CANONICAL^2]] /; SameQ[Dimensions[I$SYMPLECTIC$MATRIX],Dimensions[ConstantArray[I$VARIABLES$CANONICAL,I$DIMENSION$CANONICAL]]] ;
(* ################################################################################################################################################################ *)
(* SYMPLECTIC TEST (MAP) *)
(* ################################################################################################################################################################ *)
ClearAll[I$SYMPLECTIC$MAP$Q] ;
I$SYMPLECTIC$MAP$Q::usage = "
I$SYMPLECTIC$MAP$Q[MAP] -- (function) test symplectic condition for given map <MAP>
" ;
I$SYMPLECTIC$MAP$Q[MAP_?ArrayQ] := I$SYMPLECTIC$MATRIX$Q[D[MAP,List[I$VARIABLES$CANONICAL]]] /; SameQ[Length[MAP],I$DIMENSION$CANONICAL] ;
(* ################################################################################################################################################################ *)
(* DERIVATIVE OF HAMILTONIAN VECTOR FIELD OR CANONICAL MAP FOR SELECTED COMPONENTS *)
(* ################################################################################################################################################################ *)
ClearAll[I$DERIVATIVE] ;
I$DERIVATIVE::usage = "
I$DERIVATIVE[DATA] -- (function) compute derivatives for given vector field (or canonical map) <DATA> (list), with or without parameters, add flags to parameters, i.e. KNOB_I -> FLAG_I*KNOB_I
" ;
Options[I$DERIVATIVE] := List[
Rule["MAP",Map], (* -- MAP FUNCTION (E.G. Map, ParallelMap, I$PARALLEL$MAP) *)
Rule["PROLOG",Identity], (* -- PROLOG FUNCTION (ACTS ON INPUT) *)
Rule["EPILOG",Identity] (* -- EPILOG FUNCTION (ACTS AFTER EACH APPLICATION OF DERIVATIVE) *)
] ;
I$DERIVATIVE[ (* -- GENERATE VECTOR FIELD (OR MAP) FOR DERIVATIVES FOR GIVEN VECTOR FIELD (OR CANONICAL MAP) (OUTPUT ORDERING IS IDENTICAL TO I$COMPONENTS OR I$VARIABLES$DERIVATIVE) *)
DATA_List, (* -- VECTOR FIELD OR CANONICAL MAP WITH EXPLICIT DEPENDENCE ON CANONICAL VARIABLES AND PARAMETERS (WITHOUT PARAMETRIC FLAGS) *)
OPTIONS:OptionsPattern[] (* -- OPTION(S) *)
] := Catch[
Block[
{FUNCTION,PROLOG,EPILOG,RESULT,PARAMETER,VARIABLE,RULE},
(* SET FUNCTIONS *)
FUNCTION = OptionValue["MAP"] ;
PROLOG = OptionValue["PROLOG"] ;
EPILOG = OptionValue["EPILOG"] ;
(* PROCESS INPUT *)
RESULT = FUNCTION[PROLOG,DATA] ;
(* ADD FLAGS TO PARAMETERS *)
RESULT = ReplaceAll[RESULT,I$RULE$PARAMETRIC] ;
(* DIRECT REPLACEMENT RULES (CONVERT INPUT TO GENERIC VARIABLES) *)
ClearAll[I$GP] ;
ClearAll[I$GV] ;
PARAMETER = Array[I$GP,I$DIMENSION$DEVIATION] ;
VARIABLE = Array[I$GV,I$DIMENSION$CANONICAL] ;
VARIABLE = Flatten[Outer[Apply,VARIABLE,List[PARAMETER],1]] ;
(* APPLY RULES *)
RESULT = FUNCTION[ReplaceAll[I$RULE$COMPONENTS],RESULT] ;
(* INVERSE REPLACEMENT RULES *)
RULE = Dispatch[Map[Reverse,Normal[I$RULE$COMPONENTS]]] ;
(* COMPUTE DERIVATIVES (FOR EACH COMPONENT) (DERIVATIVE IS COMPUTED FOR GENERIC GENERIC VARIABLES) *)
RESULT = FUNCTION[
Function[
Block[
{VALUE,LIST,DERIVATIVE},
VALUE = First[Slot[1]] ;
LIST = Rest[Slot[1]] ;
DERIVATIVE = Reverse[Transpose[List[PARAMETER,LIST]]] ;
DERIVATIVE = DeleteCases[DERIVATIVE,List[_,0]] ;
DERIVATIVE = Fold[Composition[EPILOG,D],Part[RESULT,VALUE],DERIVATIVE] ;
Fold[ReplaceAll,DERIVATIVE,List[I$RULE$DERIVATIVE,RULE]]
]
],
I$COMPONENTS
] ;
(* OUTPUT *)
RESULT
]
] /; And[
SameQ[Length[DATA],I$DIMENSION$CANONICAL],
SameQ[Head[I$COMPONENTS],List]
] ;
(* ################################################################################################################################################################ *)
(* POISSON BRACKET *)
(* ################################################################################################################################################################ *)
ClearAll[I$POISSON$BRACKET] ;
I$POISSON$BRACKET::usage = "
I$POISSON$BRACKET[F,G] -- (function) compute Poisson bracket between two canonical observables <F> and <G> (functions of canonical variables)
" ;
I$POISSON$BRACKET := Function[Dot[D[Slot[1],List[I$VARIABLES$CANONICAL]],I$SYMPLECTIC$MATRIX,D[Slot[2],List[I$VARIABLES$CANONICAL]]]] ;
(* ################################################################################################################################################################ *)
(* GRADIENT FIELD (HAMILTONIAN) *)
(* ################################################################################################################################################################ *)
ClearAll[I$GRADIENT$FIELD] ;
I$GRADIENT$FIELD::usage = "
I$GRADIENT$FIELD[HAMILTONIAN] -- (function) compute gradient vector field for given Hamiltonian function <HAMILTONIAN> (function of canonical variables)
" ;
I$GRADIENT$FIELD := Function[D[Slot[1],List[I$VARIABLES$CANONICAL]]] ;
(* ################################################################################################################################################################ *)
(* VECTOR FIELD (HAMILTONIAN) *)
(* ################################################################################################################################################################ *)
ClearAll[I$VECTOR$FIELD] ;
I$VECTOR$FIELD::usage = "
I$VECTOR$FIELD[HAMILTONIAN] -- (function) compute Hamiltonian vector field for given Hamiltonian function <HAMILTONIAN> (function of canonical variables)
" ;
I$VECTOR$FIELD := Function[Dot[I$SYMPLECTIC$MATRIX,I$GRADIENT$FIELD[Slot[1]]]] ;
(* ################################################################################################################################################################ *)
(* EQUATIONS (DSOLVE) *)
(* ################################################################################################################################################################ *)
ClearAll[I$DSOLVE$SYSTEM] ;
I$DSOLVE$SYSTEM::usage = "
I$DSOLVE$SYSTEM[VECTOR] -- generate DSolve[] input template (flow with generic initial conditions) for given hamiltonian vector field <VECTOR> (function of canonical variables)
" ;
I$DSOLVE$SYSTEM := Function[Join[Thread[Equal[D[Through[I$DSOLVE$VARIABLES[I$PARAMETER]],I$PARAMETER],ReplaceAll[Slot[1],Thread[Rule[I$DSOLVE$VARIABLES,Through[I$DSOLVE$VARIABLES[I$PARAMETER]]]]]]],I$DSOLVE$INITIALS]] ;
(* ################################################################################################################################################################ *)
(* USE DSolve[] TO FIND SOLUTION (ACTS ON LIST OF SOVABLE HAMILTONIANS) *)
(* ################################################################################################################################################################ *)
ClearAll[I$DSOLVE] ;
I$DSOLVE::usage = "
I$DSOLVE[LIST] -- solve Hamiltonian equations with DSolve[] for given list of sovable Hamiltonan functions <LIST>
" ;
I$DSOLVE := Map[Composition[Simplify,ReplaceAll[I$DSOLVE$RULE],Function[Through[Slot[1][I$PARAMETER]]],Function[Apply[DSolveValue,List[Slot[1],I$DSOLVE$VARIABLES,I$PARAMETER]]],I$DSOLVE$SYSTEM,I$VECTOR$FIELD]] ;
(* ################################################################################################################################################################ *)
(* VECTOR FIELD DERIVATIVE *)
(* ################################################################################################################################################################ *)
ClearAll[I$VECTOR$FIELD$DERIVATIVE] ;
I$VECTOR$FIELD$DERIVATIVE::usage = "
I$VECTOR$FIELD$DERIVATIVE[VECTOR] -- add vector field for derivatives to given canonical vector field <VECTOR> (function of canonical variables), add flags to parameters, i.e. KNOB_I -> FLAG_I*KNOB_I
" ;
I$VECTOR$FIELD$DERIVATIVE := Function[Flatten[List[ReplaceAll[Slot[1],I$RULE$PARAMETRIC],I$DERIVATIVE[Slot[1]]]]] ;
(* ################################################################################################################################################################ *)
(* MAP DERIVATIVE *)
(* ################################################################################################################################################################ *)
ClearAll[I$MAP$DERIVATIVE] ;
I$MAP$DERIVATIVE::usage = "
I$MAP$DERIVATIVE[MAP] -- compute state map, add map for derivatives to given canonical map <MAP> (function of canonical variables), add aperture flag, parameters and flags for parameters), i.e. KNOB_I -> FLAG_I*KNOB_I
" ;
I$MAP$DERIVATIVE := Function[Flatten[List[I$FLAG,I$VARIABLES$PARAMETRIC,I$VECTOR$FIELD$DERIVATIVE[Slot[1]]]]] ;
(* ################################################################################################################################################################ *)
(* MAKE (STANDARD) INITIAL CONDITION *)
(* ################################################################################################################################################################ *)
(* NOTE: STATE (FULL INITIAL CONDITION) STRUCTURE {<FLAG>,<KNOB_1>,<KNOB_2>,...,<CANONICAL_1>,<CANONICAL_2>,...,<DERIVATIVE_1>,<DERIVATIVE_2>,...} *)
(* <FLAG> -- APERTURE FLAG (0/1) *)
(* <KNOB_1>,<KNOB_2>,... -- PARAMETERS *)
(* <CANONICAL_1>,<CANONICAL_2>,... -- CANONICAL VARIABLES *)
(* <DERIVATIVE_1>,<DERIVATIVE_2>,... -- DERIVATIVES *)
(* ################################################################################################################################################################ *)
ClearAll[I$MAKE$INITIAL] ;
I$MAKE$INITIAL::usage = "
I$MAKE$INITIAL[KNOB,CANONICAL] -- generate standard initial state for given list of parameters <KNOB> (list) and list of canonical coordinates <CANONICAL> (list)
I$MAKE$INITIAL[CANONICAL] -- generate standard initial state for given list of canonical coordinates <CANONICAL> (list)
" ;
I$MAKE$INITIAL[ (* -- GENERATE INITIAL CONDITION (TAYLOR MAP COMPUTATION) *)
KNOB_List, (* -- LIST OF VALUES FOR PARAMETER VARIABLES *)
CANONICAL_List (* -- LIST OF VALUES FOR CANONICAL VARIABLES *)
] := Catch[
N[PadRight[Flatten[List[1,KNOB,CANONICAL,If[UnsameQ[I$VARIABLES$DEVIATION,List[]],Transpose[D[I$VARIABLES$CANONICAL,List[I$VARIABLES$DEVIATION]]],List[]]]],I$DIMENSION$VARIABLES]]
] /; And[
SameQ[Length[KNOB],I$DIMENSION$PARAMETRIC],
SameQ[Length[CANONICAL],I$DIMENSION$CANONICAL]
] ;
(* ABBREVIATION(S) *)
I$MAKE$INITIAL[CANONICAL_List] := I$MAKE$INITIAL[ConstantArray[0,I$DIMENSION$PARAMETRIC],CANONICAL] ;
(* ################################################################################################################################################################ *)
(* MAKE STATE FROM (CANONICAL) COMPONENTS (STATE REPRESENTATION) *)
(* ################################################################################################################################################################ *)
ClearAll[I$MAKE$STATE] ;
I$MAKE$STATE::usage = "
I$MAKE$STATE[KNOB,COMPONENT] -- convert series representation to state for given list of parameters <KNOB> (list) and components <COMPONENT> (list)
I$MAKE$STATE[COMPONENT] -- convert series representation to state for given list of canonical components <COMPONENT> (list)
" ;
I$MAKE$STATE[ (* -- CONVERT CANONICAL COMPONENTS TO STATE *)
KNOB_List, (* -- PARAMETERS (LIST) *)
COMPONENT_List (* -- CANONICAL COMPONENTS (LIST) *)
] := Block[
{DERIVATIVE},
DERIVATIVE = Map[
Function[
Block[
{INDEX,SIGNATURE},
INDEX = First[Slot[1]] ;
SIGNATURE = Rest[Slot[1]] ;
SIGNATURE = Apply[Sequence,Transpose[List[I$VARIABLES$DEVIATION,SIGNATURE]]] ;
D[Part[COMPONENT,INDEX],SIGNATURE]
]
],
I$COMPONENTS
] ;
Flatten[N[ReplaceAll[List[1,KNOB,COMPONENT,DERIVATIVE],Dispatch[Thread[Rule[I$VARIABLES,0]]]]]]
] /; And[
SameQ[Length[KNOB],I$DIMENSION$PARAMETRIC],
SameQ[Length[COMPONENT],I$DIMENSION$CANONICAL]
] ;
(* ABBREVIATION(S) *)
I$MAKE$STATE[COMPONENT_List] := I$MAKE$STATE[ConstantArray[0,I$DIMENSION$PARAMETRIC],COMPONENT] ;
(* ################################################################################################################################################################ *)
(* MAKE CANONICAL COMPONENTS FROM STATE *)
(* ################################################################################################################################################################ *)
ClearAll[I$MAKE$COMPONENTS] ;
I$MAKE$COMPONENTS::usage = "
I$MAKE$COMPONENTS[STATE] -- make canonical components (series representation) for given state <STATE> (list)
" ;
I$MAKE$COMPONENTS[ (* -- MAKE CANONICAL COMPONENTS FROM GIVEN STATE (SERIES REPRESENTATION) *)
STATE_List (* -- STATE (LIST) *)
] := Block[
{ZERO,PARAMETER,DERIVATIVE},
ZERO = Drop[STATE,1] ;
ZERO = Drop[ZERO,I$DIMENSION$PARAMETRIC] ;
ZERO = Take[ZERO,I$DIMENSION$CANONICAL] ;
If[
UnsameQ[I$DIMENSION$DERIVATIVE,0],
PARAMETER = Drop[STATE,1] ;
PARAMETER = Take[PARAMETER,I$DIMENSION$PARAMETRIC] ;
DERIVATIVE = Drop[STATE,1] ;
DERIVATIVE = Drop[DERIVATIVE,I$DIMENSION$PARAMETRIC] ;
DERIVATIVE = Drop[DERIVATIVE,I$DIMENSION$CANONICAL] ;
DERIVATIVE = Map[Total,I$MAKE$FUNCTIONS[DERIVATIVE]] ;
Plus[ZERO,DERIVATIVE],
ZERO
]
] /; SameQ[Length[STATE],I$DIMENSION$VARIABLES] ;
(* ################################################################################################################################################################ *)
(* GENERATE NDSOLVE EQUATIONS FOR GIVEN TOTAL VECTOR FIELD (I.E. WITH DERIVATIVES) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$FLOW] ;
I$NDSOLVE$FLOW::usage = "
I$NDSOLVE$FLOW[VECTOR] -- generate flow equations to be used with NDSolve[] for given total vector field <VECTOR> (list)
" ;
I$NDSOLVE$FLOW := Function[Thread[Equal[D[Through[I$NDSOLVE$VARIABLES[I$PARAMETER]],I$PARAMETER],ReplaceAll[Slot[1],Dispatch[Thread[Rule[I$NDSOLVE$VARIABLES,Through[I$NDSOLVE$VARIABLES[I$PARAMETER]]]]]]]]] ;
(* ################################################################################################################################################################ *)
(* GENERATE NDSOLVE EQUATIONS WITH INITIAL CONDITIONS FOR GIVEN TOTAL VECTOR FIELD (I.E. WITH DERIVATIVES) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$SYSTEM] ;
I$NDSOLVE$SYSTEM::usage = "
I$NDSOLVE$SYSTEM[VECTOR] -- generate NDSolve[] template (equations and initial conditions) for given total vector field <VECTOR>
" ;
I$NDSOLVE$SYSTEM := Function[Join[I$NDSOLVE$FLOW[Slot[1]],I$NDSOLVE$INITIALS]] ;
(* ################################################################################################################################################################ *)
(* SET NDSOLVE METHOD (PREDIFINED OR VALID METHOD FOR TIME INTEGRATION), ALL PREDIFINED METHODS ARE SYMPLECTIC *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$SET$METHOD] ;
I$NDSOLVE$SET$METHOD::usage = "
I$NDSOLVE$SET$METHOD[METHOD] -- set NDSolve[] method with <METHOD> being one of the predefined methods (integer = 1,2,...,8) or any valid NDSolve[] method for \"TimeIntegration\"
" ;
I$NDSOLVE$SET$METHOD := Function[
Which[
SameQ[Slot[1],1], (* -- FS SRK10 *)
List["FixedStep",Rule[Method,List["ImplicitRungeKutta",Rule["DifferenceOrder",10],Rule["Coefficients","ImplicitRungeKuttaGaussCoefficients"],Rule["ImplicitSolver",List["Newton",Rule[AccuracyGoal,MachinePrecision],Rule[PrecisionGoal,MachinePrecision],Rule["IterationSafetyFactor",1]]]]]],
SameQ[Slot[1],2], (* -- FS SRK20 *)
List["FixedStep",Rule[Method,List["ImplicitRungeKutta",Rule["DifferenceOrder",20],Rule["Coefficients","ImplicitRungeKuttaGaussCoefficients"],Rule["ImplicitSolver",List["Newton",Rule[AccuracyGoal,MachinePrecision],Rule[PrecisionGoal,MachinePrecision],Rule["IterationSafetyFactor",1]]]]]],
SameQ[Slot[1],3], (* -- FS SRK30 *)
List["FixedStep",Rule[Method,List["ImplicitRungeKutta",Rule["DifferenceOrder",30],Rule["Coefficients","ImplicitRungeKuttaGaussCoefficients"],Rule["ImplicitSolver",List["Newton",Rule[AccuracyGoal,MachinePrecision],Rule[PrecisionGoal,MachinePrecision],Rule["IterationSafetyFactor",1]]]]]],
SameQ[Slot[1],4], (* -- FS SRK40 *)
List["FixedStep",Rule[Method,List["ImplicitRungeKutta",Rule["DifferenceOrder",40],Rule["Coefficients","ImplicitRungeKuttaGaussCoefficients"],Rule["ImplicitSolver",List["Newton",Rule[AccuracyGoal,MachinePrecision],Rule[PrecisionGoal,MachinePrecision],Rule["IterationSafetyFactor",1]]]]]],
SameQ[Slot[1],5], (* -- AS SRK10 *)
List["ImplicitRungeKutta",Rule["DifferenceOrder",10],Rule["Coefficients","ImplicitRungeKuttaGaussCoefficients"],Rule["ImplicitSolver",List["Newton",Rule[AccuracyGoal,MachinePrecision],Rule[PrecisionGoal,MachinePrecision],Rule["IterationSafetyFactor",1]]]],
SameQ[Slot[1],6], (* -- AS SRK20 *)
List["ImplicitRungeKutta",Rule["DifferenceOrder",20],Rule["Coefficients","ImplicitRungeKuttaGaussCoefficients"],Rule["ImplicitSolver",List["Newton",Rule[AccuracyGoal,MachinePrecision],Rule[PrecisionGoal,MachinePrecision],Rule["IterationSafetyFactor",1]]]],
SameQ[Slot[1],7], (* -- SPRK4 *)
List["FixedStep",Rule[Method,List["SymplecticPartitionedRungeKutta",Rule["DifferenceOrder",4],Rule["PositionVariables",Through[I$VARIABLES$CANONICAL$Q[I$PARAMETER]]]]]],
SameQ[Slot[1],8], (* -- SPRK8 *)
List["FixedStep",Rule[Method,List["SymplecticPartitionedRungeKutta",Rule["DifferenceOrder",8],Rule["PositionVariables",Through[I$VARIABLES$CANONICAL$Q[I$PARAMETER]]]]]],
True, (* -- USER *)
Slot[1]
]
] ;
(* ################################################################################################################################################################ *)
(* SET NDSOLVE OPTIONS (INTEGRATION STEP SIZE, NUMBER OF INTEGRATION STEPS AND INTEGRATION METHOD) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$SET$OPTIONS] ;
I$NDSOLVE$SET$OPTIONS::usage = "
I$NDSOLVE$SET$OPTIONS[STEP,LENGTH,METHOD] -- set (subset of) NDSolve[] options for given number of integration steps <STEP> (integer), integration length <LENGTH> (real) and integration method <METHOD> (valid method)
" ;
I$NDSOLVE$SET$OPTIONS[ (* -- SET NDSOLVE OPTIONS *)
STEP_Integer, (* -- NUMBER OF INTEGRATION STEPS (INTEGER) *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
METHOD_ (* -- INTEGRATION METHOD (VALID NDSolve[] METHOD OR PREDEFINED) *)
] := List[
Rule[Method,List[Rule["EquationSimplification","Solve"],Rule["ParametricCaching",None],Rule["ParametricSensitivity",None],Rule["TimeIntegration",I$NDSOLVE$SET$METHOD[METHOD]]]],
Rule[StartingStepSize,Divide[LENGTH,STEP]],
Rule[MaxStepFraction,Divide[1,STEP]],
Rule[Compiled,True],
Rule[MaxSteps,Infinity],
Rule[DependentVariables,I$NDSOLVE$VARIABLES]
] ;
(* ################################################################################################################################################################ *)
(* NDSOLVE STATE (TOTAL VECTOR FIELD) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$STATE] ;
I$NDSOLVE$STATE::usage = "
I$NDSOLVE$STATE[VECTOR,STEP,LENGTH,METHOD] -- generate state object from total vector field <VECTOR> (list) to be integrated for number of steps <STEP> (integer) over length <LENGTH> (real) and integration method <METHOD>
" ;
I$NDSOLVE$STATE[ (* -- GENERATE STATE (TOTAL VECTOR FIELD) *)
VECTOR_List, (* -- TOTAL VECTOR FIELD *)
STEP_Integer, (* -- NUMBER OF INTEGRATION STEPS (INTEGER) *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
METHOD_ (* -- INTEGRATION METHOD *)
] := Apply[
ParametricNDSolveValue[
N[I$NDSOLVE$SYSTEM[ReplaceAll[VECTOR,Dispatch[Thread[Rule[I$FLAG$PARAMETRIC,1]]]]]],
I$NDSOLVE$VARIABLES,
List[I$PARAMETER,0,LENGTH],
I$NDSOLVE$PARAMETERS,
I$NDSOLVE$SET$OPTIONS[STEP,LENGTH,METHOD]
]
] ;
(* ################################################################################################################################################################ *)
(* NDSOLVE STATE (VECTOR FIELD) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$STATE$VECTOR] ;
I$NDSOLVE$STATE$VECTOR::usage = "
I$NDSOLVE$STATE$VECTOR[VECTOR,STEP,LENGTH,METHOD] -- generate state object from vector field <VECTOR> (list) to be integrated for number of steps <STEP> (integer) over length <LENGTH> (real) and integration method <METHOD>
" ;
I$NDSOLVE$STATE$VECTOR[ (* -- GENERATE STATE (VECTOR FIELD) *)
VECTOR_List, (* -- VECTOR FIELD *)
STEP_Integer, (* -- NUMBER OF INTEGRATION STEPS (INTEGER) *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
METHOD_ (* -- INTEGRATION METHOD *)
] := I$NDSOLVE$STATE[I$VECTOR$FIELD$DERIVATIVE[VECTOR],STEP,LENGTH,METHOD] ;
(* ################################################################################################################################################################ *)
(* NDSOLVE STATE (HAMILTONIAN) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$STATE$SCALAR] ;
I$NDSOLVE$STATE$SCALAR::usage = "
I$NDSOLVE$STATE$SCALAR[HAMILTONIAN,STEP,LENGTH,METHOD] -- generate state object from Hamiltonian <HAMILTONIAN> to be integrated for number of steps <STEP> (integer) over length <LENGTH> (real) and integration method <METHOD>
" ;
I$NDSOLVE$STATE$SCALAR[ (* -- GENERATE STATE (HAMILTONIAN) *)
HAMILTONIAN_, (* -- HAMILTONIAN *)
STEP_Integer, (* -- NUMBER OF INTEGRATION STEPS (INTEGER) *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
METHOD_ (* -- INTEGRATION METHOD *)
] := I$NDSOLVE$STATE$VECTOR[I$VECTOR$FIELD[HAMILTONIAN],STEP,LENGTH,METHOD] ;
(* ################################################################################################################################################################ *)
(* NDSOLVE STATE ITERATION (FINAL STATE) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$ITERATE] ;
I$NDSOLVE$ITERATE::usage = "
I$NDSOLVE$ITERATE[OBJECT,LENGTH,INITIAL] -- iterate NDSolve[] state <OBJECT> up to length <LENGTH> (real) (should be less then total length) with initial condinions <INITIAL> and return final state
" ;
I$NDSOLVE$ITERATE[ (* -- STATE ITERATOR (LAST STEP OUTPUT) *)
OBJECT_, (* -- STATE TO ITERATE *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
INITIAL_List (* -- INITIAL CONDITION (STATE) *)
] := Catch[
Block[
{FLAG,LIST},
FLAG = First[INITIAL] ;
LIST = Drop[INITIAL,1] ;
If[Less[FLAG,0.5],Throw[INITIAL]] ;
LIST = Flatten[List[1.0,Take[LIST,I$DIMENSION$PARAMETRIC],Through[OBJECT[LIST][LENGTH]]]] ;
Developer`ToPackedArray[LIST]
]
] /; SameQ[Length[INITIAL],I$DIMENSION$VARIABLES] ;
(* ################################################################################################################################################################ *)
(* NDSOLVE STATE ITERATION (OUTPUT AT EACH INTEGRATION STEP) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE$ITERATE$LIST] ;
I$NDSOLVE$ITERATE$LIST::usage = "
I$NDSOLVE$ITERATE$LIST[OBJECT,LENGTH,INITIAL] -- iterate NDSolve[] state <OBJECT> up to length <LENGTH> (real) with initial condinions <INITIAL> (list) and return state at each integration step
" ;
I$NDSOLVE$ITERATE$LIST[ (* -- STATE ITERATOR (OUTPUT AT EACH INTEGRATION STEP) *)
OBJECT_, (* -- STATE TO ITERATE *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
INITIAL_List (* -- INITIAL CONDITION *)
] := Catch[
Block[
{FLAG,LIST,TIME,NUMBER,VARIABLE,PARAMETER},
FLAG = First[INITIAL] ;
If[Less[FLAG,0.5],Throw[INITIAL]] ;
LIST = Drop[INITIAL,1] ;
LIST = OBJECT[LIST] ;
TIME = Flatten[First[LIST]["Grid"]] ;
NUMBER = Length[TIME] ;
VARIABLE = Transpose[Through[LIST["ValuesOnGrid"]]] ;
PARAMETER = Map[Function[ConstantArray[Slot[1],NUMBER]],Take[Drop[INITIAL,1],I$DIMENSION$PARAMETRIC]] ;
PARAMETER = If[UnsameQ[PARAMETER,List[]],Transpose[PARAMETER],Nothing] ;
FLAG = Transpose[List[ConstantArray[FLAG,NUMBER]]] ;
LIST = Map[Flatten,Transpose[List[TIME,FLAG,PARAMETER,VARIABLE]],1] ;
List[Rest[Last[LIST]],LIST]
]
] /; SameQ[Length[INITIAL],I$DIMENSION$VARIABLES] ;
(* ################################################################################################################################################################ *)
(* NDSOLVE INTEGRATOR (RETURNS FUNCTION THAT ACTS ON STATE) *)
(* ################################################################################################################################################################ *)
(* NOTE: ALL PARAMETRIC FLAGS ARE SET TO 1, I.E. FLAG_I \[Rule] 1 *)
(* NOTE: EQUATIONS CAN BE SOLVED INDEPENDENTLY (NOT IMPLEMENTED) *)
(* ################################################################################################################################################################ *)
ClearAll[I$NDSOLVE] ;
I$NDSOLVE::usage = "
I$NDSOLVE[HAMILTONIAN,STEP,LENGTH,METHOD] -- generate NDSolve[] element for given Hamiltonian <HAMILTONIAN>, number of integration steps <STEP> (integer), integration length <LENGTH> (real) and integration method <METHOD>
I$NDSOLVE[VECTOR,STEP,LENGTH,METHOD] -- generate NDSolve[] element for given vector field <VECTOR> (canonical or total), number of integration steps <STEP> (integer), integration length <LENGTH> (real) and integration method <METHOD>
I$NDSOLVE[HAMILTONIAN,STEP,LENGTH,METHOD,ITERATOR] -- generate NDSolve[] element for given Hamiltonian <HAMILTONIAN>, number of integration steps <STEP> (integer), integration length <LENGTH> (real), integration method <METHOD> and iterator function <ITERATOR> (I$NDSOLVE$ITERATE OR I$NDSOLVE$ITERATE$LIST)
I$NDSOLVE[VECTOR,STEP,LENGTH,METHOD,ITRERATOR] -- generate NDSolve[] element for given vector field <VECTOR> (canonical or total), number of integration steps <STEP> (integer), integration length <LENGTH> (real), integration method <METHOD> and iterator function <ITERATOR> (I$NDSOLVE$ITERATE OR I$NDSOLVE$ITERATE$LIST)
" ;
I$NDSOLVE[ (* -- GENERATE NDSOLVE BASED MAP (ACTS ON INITIAL CONDITION) *)
HAMILTONIAN_, (* -- HAMILTONIAN FUNCTION *)
STEP_Integer, (* -- NUMBER OF INTEGRATION STEPS (INTEGER) *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
METHOD_, (* -- INTEGRATION METHO *)
ITERATOR_:I$NDSOLVE$ITERATE (* -- ITERATOR FUNCTION (I$NDSOLVE$ITERATE OR I$NDSOLVE$ITERATE$LIST) *)
] := Block[
{STATE},
STATE = I$NDSOLVE$STATE$SCALAR[HAMILTONIAN,STEP,LENGTH,METHOD] ;
ReleaseHold[Hold[Function][Hold[ITERATOR][STATE,LENGTH,Slot[1]]]]
] ;
I$NDSOLVE[ (* -- GENERATE NDSOLVE BASED MAP (ACTS ON INITIAL CONDITION) *)
VECTOR_List, (* -- VECTOR FIELD OR TOTAL VECTOR FIELD *)
STEP_Integer, (* -- NUMBER OF INTEGRATION STEPS (INTEGER) *)
LENGTH_Real, (* -- INTEGRATION LENGTH (REAL) *)
METHOD_, (* -- INTEGRATION METHO *)
ITERATOR_:I$NDSOLVE$ITERATE (* -- ITERATOR FUNCTION (I$NDSOLVE$ITERATE OR I$NDSOLVE$ITERATE$LIST) *)
] := Block[
{STATE},
STATE = If[
SameQ[Length[VECTOR],I$DIMENSION$CANONICAL],
I$NDSOLVE$STATE$VECTOR[VECTOR,STEP,LENGTH,METHOD],
I$NDSOLVE$STATE[VECTOR,STEP,LENGTH,METHOD]
] ;
ReleaseHold[Hold[Function][Hold[ITERATOR][STATE,LENGTH,Slot[1]]]]
] ;
(* ################################################################################################################################################################ *)
(* PARAMETRIC CLOSED ORBIT (NUMERICAL ROOT FINDING) *)
(* ################################################################################################################################################################ *)
(* NOTE: <MASK> = {...,1,...,0,...} WITH 1(0) INDICATING AN OSCILLATING (DRIFTING) PLANE(S), E.G. <PLANE> = {1,0} <=> {{Q1,P1},{Q2,P2}}, {Q1,P1} IS OSCILLATING AND {Q2,P2} IS DRIFTING *)
(* ################################################################################################################################################################ *)
ClearAll[I$ORBIT] ;
I$ORBIT::usage = "
I$ORBIT[ORDER,MAP] -- compute parametric closed orbit for given one turn map <MAP> (state map) up to order <ORDER> (integer)
I$ORBIT[ORDER,MAP,MASK] -- compute parametric closed orbit for given one turn map <MAP> (state map) up to order <ORDER> (integer) with drift planes <MASK> (list of integers)
" ;
Options[I$ORBIT] = List[
Rule["MAX",100], (* -- MAXIMUM NUMBER OF ITERATIONS (INTEGER) *)
Rule["METHOD","Newton"], (* -- SOLVE METHOD *)
Rule["VERBOSE",False] (* -- VERBOSE FLAG *)
] ;
I$ORBIT[ (* -- COMPUTE PARAMETRIC CLOSED ORBIT *)
ORDER_Integer, (* -- ORDER (INTEGER) *)
MAP_, (* -- STATE MAP (FUNCTION) *)
OPTIONS:OptionsPattern[] (* -- OPTION(S) *)
] := Block[
{COEFFICIENT,RESULT,ZERO,INITIAL,POSITION,MAX,ALL,LOOP,FIX,REPLACE,VALUE,INDEX,SOLUTION},
SetAttributes[COEFFICIENT,NHoldAll] ;
(* GENERATE GENERIC CLOSED ORBIT COEFFICIENTS *)
RESULT = Flatten[List[1.0,Array[COEFFICIENT,Subtract[I$DIMENSION$VARIABLES,1]]]] ;
(* CONVERT COEFFICIENT REPRESENTATION TO SERIES REPRESENTATION *)
RESULT = I$MAKE$COMPONENTS[RESULT] ;
(* ZERO ORDER COEFFICIENTS *)
ZERO = Chop[ReplaceAll[RESULT,Thread[Rule[I$VARIABLES,0]]]] ;
(* PARAMETRIC PART OF CLOSED ORBIT (REMOVE CANONICAL VARIABLES) *)
RESULT = ReplaceAll[RESULT,Thread[Rule[I$VARIABLES$CANONICAL,0]]] ;
(* GENERATE COEFFICIENT REPRESENTATION OF PARAMETRIC PART (NONPARAMETRIC COEFFICIENTS ARE REPLACED BY ZEROS) *)
RESULT = I$MAKE$STATE[ConstantArray[0,I$DIMENSION$PARAMETRIC],RESULT] ;
RESULT = Rest[RESULT] ;
RESULT = Drop[RESULT,I$DIMENSION$PARAMETRIC] ;
RESULT = Drop[RESULT,I$DIMENSION$CANONICAL] ;
RESULT = Rationalize[RESULT] ;
(* GROUP COEFFICIENTS BY ORDER AND ADD ZERO ORDER COEFFICIENTS *)
RESULT = Values[GroupBy[Transpose[List[I$COMPONENTS,RESULT]],Composition[Total,Rest,First]]] ;
RESULT = Map[Composition[Last,Transpose],RESULT] ;
RESULT = Join[List[ZERO],RESULT] ;
(* GENERATE (ZERO) INITIAL CONDITIONS FOR COEFFICIENTS (ZEROS) *)
INITIAL = Map[Variables,RESULT] ;
INITIAL = Map[Function[Transpose[List[Slot[1],ConstantArray[N[0],Length[Slot[1]]]]]],INITIAL] ;
(* ADD PARAMETERS TO COEFFICIENTS *)
RESULT = Flatten[List[1,ConstantArray[0,I$DIMENSION$PARAMETRIC],RESULT]] ;
(* SET POSITIONS OF GENERIC COEFFICIENTS GROUPED BY ORDER STARTING FROM ZERO ORDER *)
POSITION = Map[Composition[Flatten,Function[Map[Function[Position[RESULT,Slot[1]]],Slot[1]]],Variables],INITIAL] ;
(* SET MAXIMUM COMPUTATION ORDER *)
MAX = Min[List[Subtract[Length[DeleteCases[INITIAL,List[]]],1],ORDER]] ;
(* SOLUTION HOLDER *)
ALL = List[] ;
(* ORDER-BY-ORDER SOLUTION *)
Do[
List[
If[OptionValue["VERBOSE"],Print[LOOP]] ;
FIX[LOOP] = RESULT ;
REPLACE[LOOP] = Flatten[Delete[POSITION,1]] ;
FIX[LOOP] = ReplacePart[FIX[LOOP],Thread[Rule[REPLACE[LOOP],0]]] ;
VALUE[LOOP] = Part[INITIAL,1] ;
INDEX[LOOP] = Part[POSITION,1] ;
SOLUTION[LOOP] = FindRoot[
Equal[Part[FIX[LOOP],INDEX[LOOP]],Part[MAP[FIX[LOOP]],INDEX[LOOP]]],
VALUE[LOOP],
Rule[Evaluated,False],
Rule[MaxIterations,OptionValue["MAX"]],
Rule[Method,OptionValue["METHOD"]]
] // Quiet ;
ALL = Flatten[List[ALL,SOLUTION[LOOP]]] ;
RESULT = ReplaceAll[RESULT,ALL] ;
POSITION = Rest[POSITION] ;
INITIAL = Rest[INITIAL] ;
If[OptionValue["VERBOSE"],Print[RESULT]] ;
],
List[LOOP,0,MAX]
] ;
RESULT = ReplaceAll[RESULT,Rule[COEFFICIENT[_],0]] ;
N[I$MAKE$COMPONENTS[RESULT]]
] ;
I$ORBIT[ (* -- COMPUTE PARAMETRIC CLOSED ORBIT *)
ORDER_Integer, (* -- ORDER (INTEGER) *)
MAP_, (* -- STATE MAP (FUNCTION) *)
MASK_List, (* -- LIST OF OSCILLATING PLANES (LIST OF INTEGERS) *)
OPTIONS:OptionsPattern[] (* -- OPTION(S) *)
] := Block[
{COEFFICIENT,RESULT,ZERO,REMOVE,KEEP,SELECT,INITIAL,POSITION,MAX,ALL,FIX,REPLACE,SOLUTION,VALUE,INDEX,LOOP},
SetAttributes[COEFFICIENT,NHoldAll] ;
(* GENERATE GENERIC CLOSED ORBIT COEFFICIENTS *)
RESULT = Flatten[List[1.0,Array[COEFFICIENT,Subtract[I$DIMENSION$VARIABLES,1]]]] ;
(* CONVERT COEFFICIENT REPRESENTATION TO SERIES REPRESENTATION *)
RESULT = I$MAKE$COMPONENTS[RESULT] ;
(* REMOVE OSCILLATING PLANES *)
REMOVE = I$VARIABLES$CANONICAL ;
REMOVE = If[SameQ[I$ORDERING,"PAIRS"],Partition[REMOVE,Plus[1,1]],Transpose[Partition[REMOVE,I$DIMENSION]]] ;
KEEP = Flatten[Pick[REMOVE,MASK,0]] ;
REMOVE = Flatten[List[Pick[REMOVE,MASK,1],Complement[KEEP,I$VARIABLES$CANONICAL$Q]]] ;
KEEP = DeleteCases[KEEP,Apply[Alternatives,I$VARIABLES$CANONICAL$P]] ;
RESULT = ReplaceAll[RESULT,Thread[Rule[REMOVE,0]]] ;
(* ADD INITIAL CONDITION FOR DRIFT PLANES *)
SELECT = Transpose[ConstantArray[MASK,Plus[1,1]]] ;
SELECT = If[SameQ[I$ORDERING,"PAIRS"],Flatten[SELECT],Flatten[Transpose[SELECT]]] ;
RESULT = Pick[RESULT,SELECT,1] ;
SELECT = Pick[I$VARIABLES$CANONICAL,SELECT,0] ;
SELECT = ReplaceAll[SELECT,Thread[Rule[REMOVE,0]]] ;
RESULT = Flatten[List[RESULT,SELECT]] ;
(* ZERO ORDER COEFFICIENTS *)
ZERO = Chop[ReplaceAll[RESULT,Thread[Rule[I$VARIABLES,0]]]] ;
(* GENERATE COEFFICIENT REPRESENTATION *)
RESULT = Rationalize[I$MAKE$STATE[ConstantArray[0,I$DIMENSION$PARAMETRIC],RESULT]] ;
RESULT = Rest[Rationalize[RESULT]] ;
RESULT = Drop[RESULT,I$DIMENSION$PARAMETRIC] ;
RESULT = Drop[RESULT,I$DIMENSION$CANONICAL] ;
(* GROUP COEFFICIENTS BY ORDER AND ADD ZERO ORDER COEFFICIENTS *)
RESULT = Values[GroupBy[Transpose[List[I$COMPONENTS,RESULT]],Composition[Total,Rest,First]]] ;
RESULT = Map[Composition[Last,Transpose],RESULT] ;
RESULT = Join[List[ZERO],RESULT] ;
(* GENERATE (ZERO) INITIAL CONDITIONS FOR COEFFICIENTS (ZEROS) *)
INITIAL = Map[Variables,RESULT] ;
INITIAL = Map[Function[Transpose[List[Slot[1],ConstantArray[N[0],Length[Slot[1]]]]]],INITIAL] ;
(* ADD PARAMETERS TO COEFFICIENTS *)
RESULT = Flatten[List[1,ConstantArray[0,I$DIMENSION$PARAMETRIC],RESULT]] ;
(* SET POSITIONS OF GENERIC COEFFICIENTS GROUPED BY ORDER STARTING FROM ZERO ORDER *)
POSITION = Map[Composition[Flatten,Function[Map[Function[Position[RESULT,Slot[1]]],Slot[1]]],Variables],INITIAL] ;
(* SET MAXIMUM COMPUTATION ORDER *)
MAX = Min[List[Subtract[Length[DeleteCases[INITIAL,List[]]],1],ORDER]] ;
(* SOLUTION HOLDER *)
ALL = List[] ;
(* PERFORM ORDER-BY-ORDER SOLUTION *)
Do[
List[
If[OptionValue["VERBOSE"],Print[LOOP]] ;
FIX[LOOP] = RESULT ;
REPLACE[LOOP] = Flatten[Delete[POSITION,1]] ;
FIX[LOOP] = ReplacePart[FIX[LOOP],Thread[Rule[REPLACE[LOOP],0]]] ;
VALUE[LOOP] = Part[INITIAL,1] ;