SX1280. Getting RSSI on a specific frequency

[VSkoshchuk]

First of all, I'd like to say thank you for this great library!

Main Hardware:

• ESP32
• SX1280

For my task, I need to build an RSSI spectrum in the range of 2400-2420MHz, which will be used for signal pre-processing. But it seems I have encountered a problem. As far as I understand, RSSI can be obtained on a specific frequency only after the data packet is received. In my case, no information is transmitted with Lora, BLE, or GFSK modulation, on the frequencies I use. So I just received 0.0 as the RSSI value.

The code I use to measure RSSI:

#include <RadioLib.h>

#define LORA_SCK_PIN    5
#define LORA_MISO_PIN   3
#define LORA_MOSI_PIN   6
#define LORA_CS_PIN     7
#define LORA_RST_PIN    8
#define LORA_IO1_PIN    33

// Initialize SX1280 module
SX1280 radio = new Module(LORA_CS_PIN, LORA_IO1_PIN, LORA_RST_PIN, RADIOLIB_NC);

float startFreq = 2400.0; // Start frequency in MHz
float endFreq = 2420.0;   // End frequency in MHz
float stepSize = 1.0;     // Step size in MHz

void setup() {
  Serial.begin(115200);
  Serial.println("Hello, World!");
  vTaskDelay(1000);

  pinMode(LORA_RST_PIN, OUTPUT);
  digitalWrite(LORA_RST_PIN, HIGH);
  pinMode(LORA_SCK_PIN, OUTPUT);
  pinMode(LORA_MISO_PIN, INPUT);
  pinMode(LORA_MOSI_PIN, OUTPUT);
  SPI.begin(LORA_SCK_PIN, LORA_MISO_PIN, LORA_MOSI_PIN);

  // initialize SX1280 with default settings
  Serial.print(F("[SX1280] Initializing ... "));
  int state = radio.beginGFSK(startFreq, 800, 500, 10, 16);
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true) { delay(10); }
  }
}

void loop() {
  // Enter receive mode
  radio.startReceive();

  for (float freq = startFreq; freq <= endFreq; freq += stepSize) {
    // Set the current frequency
    int state = radio.setFrequency(freq);
    if (state != RADIOLIB_ERR_NONE) {
      Serial.print(F("Failed to set frequency: "));
      Serial.println(state);
      continue;
    }

    float rssi = radio.getRSSI();

    // Output the frequency and RSSI value
    Serial.print("Frequency: ");
    Serial.print(freq);
    Serial.print(" MHz, RSSI: ");
    Serial.print(rssi);
    Serial.println(" dBm");
  }

  // Exit receive mode
  radio.standby();

  vTaskDelay(1000);
}

Result of work:

> Frequency: 2400.00 MHz, RSSI: 0.00 dBm
> Frequency: 2401.00 MHz, RSSI: 0.00 dBm
> Frequency: 2402.00 MHz, RSSI: 0.00 dBm
> Frequency: 2403.00 MHz, RSSI: 0.00 dBm
> Frequency: 2404.00 MHz, RSSI: 0.00 dBm
> Frequency: 2405.00 MHz, RSSI: 0.00 dBm
> Frequency: 2406.00 MHz, RSSI: 0.00 dBm
> Frequency: 2407.00 MHz, RSSI: 0.00 dBm
> Frequency: 2408.00 MHz, RSSI: 0.00 dBm
> Frequency: 2409.00 MHz, RSSI: 0.00 dBm
> Frequency: 2410.00 MHz, RSSI: 0.00 dBm
> Frequency: 2411.00 MHz, RSSI: 0.00 dBm
> Frequency: 2412.00 MHz, RSSI: 0.00 dBm
> Frequency: 2413.00 MHz, RSSI: 0.00 dBm
> Frequency: 2414.00 MHz, RSSI: 0.00 dBm
> Frequency: 2415.00 MHz, RSSI: 0.00 dBm
> Frequency: 2416.00 MHz, RSSI: 0.00 dBm
> Frequency: 2417.00 MHz, RSSI: 0.00 dBm
> Frequency: 2418.00 MHz, RSSI: 0.00 dBm
> Frequency: 2419.00 MHz, RSSI: 0.00 dBm
> Frequency: 2420.00 MHz, RSSI: 0.00 dBm

Does the SX1280 support measuring RSSI on an arbitrary frequency without receiving a packet?

I would be grateful for any advice or help. I really appreciate any help you can provide.

[jgromes]

Does the SX1280 support measuring RSSI on an arbitrary frequency without receiving a packet?

It does, take a look at the docs available for the method here - it has an overload SX128x::getRSSI(bool packet) that allows to specify whether to read the RSSI of the last packet, or the instantaneous value.

[VSkoshchuk]

Thank you for your answer!

Hmm, looks like SX128x does not have such a method.

My changes:
float rssi = radio.getRSSI(false);

Building logs:

> src/main.cpp:161:36: error: no matching function for call to 'SX1280::getRSSI(bool)'
>      float rssi = radio.getRSSI(true);

[jgromes]

Then you should probably update - here is that method in the library master:

RadioLib/src/modules/SX128x/SX128x.h

Lines 787 to 792 in 75f087b

	/*!
	\brief Gets RSSI (Recorded Signal Strength Indicator).
	\param packet Whether to read last packet RSSI, or the current value.
	\returns RSSI value in dBm.
	*/
	float getRSSI(bool packet);

[VSkoshchuk]

Thanks! You are right, I have used the old version.