-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
112 lines (97 loc) · 2.84 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
plugins {
// IDE quick setup
id 'eclipse'
// Built-in gradle tasks and configurations for java libraries
id 'java-library'
// Built-in gradle tasks and configurations for maven repository publishing
id 'maven-publish'
// Built-in gradle tasks and configurations for Java code linting
id 'findbugs'
id 'checkstyle'
// Bintray artifact publishing
id 'com.jfrog.bintray' version '1.8.0'
// Auto-magic version from SCM (git) metadata
id 'net.nemerosa.versioning' version '2.6.1'
// A pretty test result logger
id 'com.adarshr.test-logger' version '1.1.2'
}
group = 'com.jossemargt'
ext {
description = 'A Tornado web framework secure cookie port'
vcsUrl = 'https://github.com/jossemargt/cookie-twist.git'
}
repositories {
jcenter()
}
dependencies {
api 'javax.servlet:javax.servlet-api:3.1.0'
testImplementation 'junit:junit:4.12'
testImplementation 'org.mockito:mockito-core:2.8+'
testImplementation 'org.powermock:powermock-module-junit4:1.7+'
testImplementation 'org.powermock:powermock-api-mockito2:1.7+'
testImplementation 'net.jodah:concurrentunit:0.4.+'
testImplementation 'pl.pragmatists:JUnitParams:1.1.1'
}
compileTestJava.options.encoding = 'UTF-8'
testlogger {
theme 'mocha'
}
task resolveVersion {
if (version == 'unspecified') {
version = versioning.info.branchId == 'master' ? versioning.info.tag : "${versioning.info.branchId}-SNAPSHOT"
}
}
jar {
dependsOn resolveVersion
manifest {
attributes('Implementation-Title': project.name,
'Implementation-Version': project.version)
}
}
task sourcesJar(type: Jar) {
dependsOn resolveVersion
from sourceSets.main.allJava
classifier "sources"
}
task javadocJar(type: Jar, dependsOn: javadoc) {
dependsOn resolveVersion
from javadoc.destinationDir
classifier = 'javadoc'
}
publishing {
publications {
Bintray(MavenPublication) {
from components.java
artifact sourcesJar
artifact javadocJar
pom.withXml {
asNode().appendNode('description', project.description)
}
}
}
}
bintray {
user = System.getenv('BINTRAY_USER')
key = System.getenv('BINTRAY_API_KEY')
publications = ['Bintray']
publish = true
pkg {
publicDownloadNumbers = true
repo = 'jvm-artifacts'
name = project.name
description = project.description
licenses = ['MIT']
websiteUrl = project.vcsUrl - '.git'
issueTrackerUrl = "${project.vcsUrl.minus('.git')}/issues"
vcsUrl = project.vcsUrl
version {
name = project.version
released = new Date()
vcsTag = project.version
}
}
}
task wrapper(type: Wrapper) {
gradleVersion = '4.7'
}
apply from: 'lint.gradle'