grammar.txt

# This is the grammar understood by the Parser

program -> declaration* EOF

declaration -> variableDeclaration | functionDeclaration | statement;



variableDeclaration -> 'var' IDENTIFIER ('=' expression)? ';'

functionDeclaration -> 'fun' function

statement -> expressionStatement | printStatement | block | ifStatement | whileStatement | forStatement

function -> IDENTIFIER '(' parameters? ')' block

parameters -> IDENTIFIER ( ',' IDENTIFIER)*

printStatement -> 'print' expression ';'

expressionStatement -> expression ';'

block -> '{' declaration* }'

ifStatement -> 'if' '(' expression ')' statement ( 'else' statement )?

whileStatement -> 'while' '(' expression ')' statement

forStatement -> 'for' '(' ( variableDeclaration | expressionStatement | ';' ) expression? ';' expression? ')' statement



expression -> commaSeparated

commaSeparated -> assignment ( "," assignment )*

assignment -> IDENTIFIER '=' assignment | logic_or

logic_or -> logic_and ( "or" logic_and )*

logic_and -> equality ( "and" equality )*

equality -> comparison ( ('!=' | '==') comparison )*

comparison -> addition ( ('<' | '>' | '<=' | '>=') addition )*

addition -> multiplication ( ( '+' | '-' ) multiplication )*

multiplication -> unary ( ( '/' | '-' ) unary )*

unary -> ( '!' | '-' ) unary | functionCall

functionCall -> primary ( '(' arguments? ')' )*

primary -> NUMBER
         | STRING
         | "false"
         | "true"
         | "nil"
         | "(" commaSeparated ")"
         | IDENTIFIER

arguments -> expression ( ',' expression )*