publish.gradle

subprojects
{
    apply plugin: 'maven-publish'
    apply plugin: 'signing'

    afterEvaluate { project ->
        publishing {
            publications {
                withType(MavenPublication) {
                    pom {
                        name = POM_NAME
                        description = POM_DESCRIPTION
                        url = POM_URL
                        licenses {
                            license {
                                name = POM_LICENCE_NAME
                                url = POM_LICENCE_URL
                                distribution = POM_LICENCE_DIST
                            }
                        }
                        developers {
                            developer {
                                id = "Tomski"
                                name = "Tom Wojciechowski"
                                email = "tomwojciechowski@asidik.com"
                            }
                        }
                        scm {
                            connection = POM_SCM_CONNECTION
                            developerConnection = POM_SCM_DEV_CONNECTION
                            url = POM_SCM_URL
                        }
                    }
                }
                //Check if we are a gradle plugin, if we are skip mavenJava
                if (!plugins.hasPlugin('java-gradle-plugin')) {
                    mavenJava(MavenPublication) {
                        from components.java

                        if (project.getPluginManager().hasPlugin("com.badlogicgames.jnigen.jnigen-gradle")) {
//                            artifact jnigenJarNativesDesktop { }
//                            ['arm64-v8a', 'armeabi-v7a', 'x86_64', 'x86'].each { id ->
//                                artifact "jnigenJarNativesAndroid${id}" { }
//                            }
//
//                            artifact jnigenJarNativesIOS { }
                        }

                        versionMapping {
                            usage('java-api') {
                                fromResolutionOf('runtimeClasspath')
                            }
                            usage('java-runtime') {
                                fromResolutionResult()
                            }
                        }
                    }
                }
            }

            repositories {
                maven {
                    url = version.endsWith('SNAPSHOT') ? getSnapshotRepositoryUrl() : getReleaseRepositoryUrl()

                    if (getRepositoryUsername() || getRepositoryPassword())
                    {
                        credentials {
                            username = getRepositoryUsername()
                            password = getRepositoryPassword()
                        }
                    }
                }
            }
        }

        signing {
            useGpgCmd()
            sign publishing.publications
        }

        //Simply using "required" in signing block doesn't work because taskGraph isn't ready yet.
        gradle.taskGraph.whenReady {
            tasks.withType(Sign) {
                onlyIf { isReleaseBuild() }
            }
        }
    }
}