-
Notifications
You must be signed in to change notification settings - Fork 2
/
StableFluids2D.compute
163 lines (139 loc) · 4.62 KB
/
StableFluids2D.compute
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
// Kernels
#pragma kernel AddValue
#pragma kernel Advection
#pragma kernel Diffusion
#pragma kernel ProjectionPt1
#pragma kernel ProjectionPt2
#pragma kernel ProjectionPt3
#pragma kernel SetBoundsX
#pragma kernel SetBoundsY
// Setup parameters
uint2 _Resolution;
// Fluid parameters
float _Alpha;
float _Beta;
float _DeltaTime;
// Add parameters
float _AddRadius;
float2 _AddPosition;
float3 _AddValue;
// Buffers
Texture2D<float3> _XIn; // Generic input buffer
RWTexture2D<float3> _XOut; // Generic output buffer
RWTexture2D<float> _PressureIn;
RWTexture2D<float> _PressureOut;
RWTexture2D<float> _Divergence;
RWTexture2D<float2> _Velocity;
RWTexture2D<float4> _DisplayTexture;
///////////////////////////////////////////////////////////////////////////
// Add Value
///////////////////////////////////////////////////////////////////////////
[numthreads(8, 8, 1)]
void AddValue(uint2 id : SV_DispatchThreadID) {
if (any(id >= _Resolution))
return;
float x = distance(id, _AddPosition);
float c = _AddRadius;
float gaussian = exp(-x*x/(2*c*c));
_XOut[id] += _AddValue * gaussian;
}
///////////////////////////////////////////////////////////////////////////
// Advection
///////////////////////////////////////////////////////////////////////////
[numthreads(8, 8, 1)]
void Advection(uint2 id : SV_DispatchThreadID)
{
if (any(id >= _Resolution))
return;
float2 dt0 = _DeltaTime * (_Resolution - 2);
float2 vec = float2(id) - dt0 * _Velocity[id];
vec = clamp(vec, 0.5, (_Resolution - 2) + 0.5);
uint2 xy0 = (uint2) vec;
uint2 xy1 = xy0 + 1;
float2 st1 = vec - xy0;
float2 st0 = 1 - st1;
_XOut[id] =
st0.x * (st0.y * _XIn[xy0] +
st1.y * _XIn[uint2(xy0.x, xy1.y)]) +
st1.x * (st0.y * _XIn[uint2(xy1.x, xy0.y)] +
st1.y * _XIn[xy1]);
}
///////////////////////////////////////////////////////////////////////////
// Diffusion
///////////////////////////////////////////////////////////////////////////
[numthreads(8, 8, 1)]
void Diffusion(uint2 id : SV_DispatchThreadID)
{
if (any(id >= _Resolution))
return;
_XOut[id] =
(_XIn[id] +
_Alpha * (_XIn[id + uint2(1, 0)] +
_XIn[id - uint2(1, 0)] +
_XIn[id + uint2(0, 1)] +
_XIn[id - uint2(0, 1)]
)) * _Beta;
}
///////////////////////////////////////////////////////////////////////////
// Projection Part 1
///////////////////////////////////////////////////////////////////////////
[numthreads(8, 8, 1)]
void ProjectionPt1(uint2 id : SV_DispatchThreadID) {
if (any(id >= _Resolution))
return;
_PressureOut[id] = 0;
_Divergence[id] = -0.5f *
((_Velocity[id + uint2(1, 0)].x - _Velocity[id - uint2(1, 0)].x) / _Resolution.x +
(_Velocity[id + uint2(0, 1)].y - _Velocity[id - uint2(0, 1)].y) / _Resolution.y);
}
///////////////////////////////////////////////////////////////////////////
// Projection Part 2
///////////////////////////////////////////////////////////////////////////
[numthreads(8, 8, 1)]
void ProjectionPt2(uint2 id : SV_DispatchThreadID) {
if (any(id >= _Resolution))
return;
_PressureOut[id] =
(_Divergence[id] +
_PressureIn[id + uint2(1, 0)] +
_PressureIn[id - uint2(1, 0)] +
_PressureIn[id + uint2(0, 1)] +
_PressureIn[id - uint2(0, 1)]
) / 4;
}
///////////////////////////////////////////////////////////////////////////
// Projection Part 3
///////////////////////////////////////////////////////////////////////////
[numthreads(8, 8, 1)]
void ProjectionPt3(uint2 id : SV_DispatchThreadID)
{
if (any(id >= _Resolution))
return;
_Velocity[id] -= 0.5 * float2(
(_PressureIn[id + uint2(1, 0)] - _PressureIn[id - uint2(1, 0)]) * _Resolution.x,
(_PressureIn[id + uint2(0, 1)] - _PressureIn[id - uint2(0, 1)]) * _Resolution.y
);
}
///////////////////////////////////////////////////////////////////////////
// Set Bounds
///////////////////////////////////////////////////////////////////////////
[numthreads(64, 1, 1)]
void SetBoundsX(uint id : SV_DispatchThreadID)
{
if (id >= _Resolution.x * 2)
return;
bool isBottomEdge = id < _Resolution.x;
int offset = isBottomEdge ? 1 : -1;
uint2 edgeId = uint2(id % _Resolution.x, isBottomEdge ? 0 : _Resolution.y - 1);
_XOut[edgeId] = _XIn[edgeId + int2(0, offset)] * float3(1, -1, 1);
}
[numthreads(64, 1, 1)]
void SetBoundsY(uint id : SV_DispatchThreadID)
{
if (id >= _Resolution.y * 2)
return;
bool isLeftEdge = id < _Resolution.y;
int offset = isLeftEdge ? 1 : -1;
uint2 edgeId = uint2(isLeftEdge ? 0 : _Resolution.x - 1, id % _Resolution.y);
_XOut[edgeId] = _XIn[edgeId + int2(offset, 0)] * float3(-1, 1, 1);
}