Thing that matches lines at same indent level

[mgraham]

I wanted to be able to select adjacent lines that have the same indent level.

Example (in ruby):

def something 
  if condition             # <-- bounds line
    do_a_thing             # <-- inner line 
    do_another_thing       # <-- inner line, cursor here
    do_yet_another_thing   # <-- inner line
  end                      # <-- bounds line
end

I searched, but couldn't find anything similar to this, so I made one myself.

It's still a little rough around the edges (and I'm still pretty new at elisp), but so far it seems to work ok.

  (defun mag/meow-thing-same-indent-lines ()
    (let ((first-line)
          (last-line)
          (start-indent (current-indentation)))
      (save-excursion
        (setq first-line (line-number-at-pos))
        (while (and (not (bobp))
                    (zerop (forward-line -1))
                    (= (current-indentation) start-indent))
          (message "[back] line: %i " (line-number-at-pos))
          (setq first-line (line-number-at-pos))))

      (save-excursion
        (setq last-line (line-number-at-pos))
        (while (and (not (eobp))
                    (zerop (forward-line 1))
                    (= (current-indentation) start-indent))
          (message "[fwd] line: %i " (line-number-at-pos))
          (setq last-line (line-number-at-pos))))

      (message "fl: %i; ll: %i" first-line last-line)
      (cons first-line last-line)))



  (defun mag/pos-at-line (line-number beginning &optional offset)
    (let ((pos))
      (save-excursion
        (forward-line (1- (- line-number (current-line))))
        (when offset
          (forward-line offset))
        (if beginning
            (beginning-of-line)
          (end-of-line))
        (setq pos (point)))
      pos))

  (defun mag/meow-thing-same-indent (beginning-offset end-offset)
    (let ((line-nums)
          (first-line)
          (last-line))
      (setq line-nums (mag/meow-thing-same-indent-lines))
      (setq first-line (car line-nums))
      (setq last-line (cdr line-nums))
      (cons (mag/pos-at-line first-line t beginning-offset)
            (mag/pos-at-line last-line nil end-offset))))


(defun mag/meow-thing-same-indent-inner ()
  (mag/meow-thing-same-indent 0 0))

(defun mag/meow-thing-same-indent-bounds ()
  (mag/meow-thing-same-indent -1 1))

(meow-thing-register 'same-indent
                     'mag/meow-thing-same-indent-inner
                     'mag/meow-thing-same-indent-bounds
                     )

Here's my thing table, including the new same-indent thing

(setq meow-char-thing-table
      '((?r . round)
        (?q . square)
        (?c . curly)
        (?a . angle)
        (?s . string)
        (?p . paragraph)
        (?l . line)
        (?f . defun)
        (?d . do/end)
        (?y . symbol)
        (?. . sentence)
        (?w . window)
        (?u . url)
        (?i . same-indent)
        (?b . buffer)))

[DogLooksGood]

This is useful when writing HTML.

[mgraham]

I actually found that this does not act as I expected it to for most cases - really when I select a block of code at a certain indent level, I want to select not only code of that indent level, but also any code at a deeper indent level.

I'll fix it eventually - I haven't gotten around to it yet.

[mgraham]

This now works properly and addresses a few edge cases too.

  ;; https://emacs.stackexchange.com/questions/16792/easiest-way-to-check-if-current-line-is-empty-ignoring-whitespace
  (defun current-line-empty-p ()
    (string-match-p "\\`\\s-*$" (thing-at-point 'line)))

  (defun mag/meow-thing-same-indent-lines ()
    (interactive)
    (let ((first-line)
          (last-line)
          (start-indent (current-indentation)))
      (save-excursion
        (setq first-line (line-number-at-pos))
        (while (and (not (bobp))
                    (zerop (forward-line -1))
                    (or (current-line-empty-p)
                        (>= (current-indentation) start-indent)))
          ;; (message "[back] line: %i " (line-number-at-pos))
          (when (and (= (current-indentation) start-indent) (not (current-line-empty-p)))
            (setq first-line (line-number-at-pos)))))

      (save-excursion
        (setq last-line (line-number-at-pos))
        (while (and (not (eobp))
                    (zerop (forward-line 1))
                    (or (current-line-empty-p)
                        (>= (current-indentation) start-indent)))
          ;; (message "[fwd] line: %i " (line-number-at-pos))
          (when (not (current-line-empty-p))
            (setq last-line (line-number-at-pos)))))

      ;; (message "fl: %i; ll: %i" first-line last-line)
      (cons first-line last-line)))

  (defun mag/pos-at-line (line-number beginning &optional offset)
    (let ((pos))
      (save-excursion
        (forward-line (1- (- line-number (current-line))))
        (when offset
          (forward-line offset))
        (if beginning
            (beginning-of-line)
          (end-of-line))
        (setq pos (point)))
      pos))

  (defun mag/meow-thing-same-indent (beginning-offset end-offset)
    (let ((line-nums)
          (first-line)
          (last-line))
      (setq line-nums (mag/meow-thing-same-indent-lines))
      (setq first-line (car line-nums))
      (setq last-line (cdr line-nums))
      (cons (mag/pos-at-line first-line t beginning-offset)
            (mag/pos-at-line last-line nil end-offset))))


  (defun mag/meow-thing-same-indent-inner ()
    (mag/meow-thing-same-indent 0 0))

  (defun mag/meow-thing-same-indent-bounds ()
    (mag/meow-thing-same-indent -1 1))

  (meow-thing-register 'same-indent
                       'mag/meow-thing-same-indent-inner
                       'mag/meow-thing-same-indent-bounds
                       )

EDIT: added the current-line-empty-p definition

[DogLooksGood]

Gonna to add it.