build.gradle

plugins {
    id 'org.ajoberstar.grgit' version '2.3.0'
}

allprojects {
    apply plugin: 'java'
    
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    
    repositories {
        jcenter()
        maven { url 'https://jitpack.io' } // SerialKiller master branch
    }
}

subprojects {
    group = 'org.megamek'
    version = '0.47.10-SNAPSHOT'
}

ext {
    mmGitRoot = 'https://github.com/MegaMek/megamek.git'
    // Work on MML or MHQ sometimes requires changes in MM as well. The maven publishing tasks use
    // these properties to append the branch name to the artifact id if the repo is not in the master
    // branch, making it available separately to the child project. 
    mmBranch = grgit.branch.current().name
    mmBranchTag = mmBranch.equals('master')? '' : '-' + mmBranch
}

// A properties_local.gradle file can be used to override any of the above options. For instance,
// rootProject.ext.gitRoot = 'file:///path/to/local/repo' will cause the release target to clone a
// local copy of the repository rather than downloading it.

def localProperties = file('properties_local.gradle')
if (localProperties.exists()) {
    apply from: localProperties
}