code7

.PAG 'CODE7'
XSPAC1	JSR OUTSPC
	BNE XSPAC2
STROUT	JSR STRLIT
STRPRT	JSR FREFAC
	TAX
	LDY #0
	INX
STRPR2	DEX
	BEQ PRTRTS
	LDA (INDEX)Y
	JSR OUTDO
	INY
	CMP #13
	BNE STRPR2
	JSR CRFIN
	JMP STRPR2
OUTSPC
	LDA CHANNL
	BEQ CRTSKP
	LDA #' 
	.BYT $2C
CRTSKP	LDA #29
	.BYT $2C
OUTQST	LDA #'?
OUTDO	JSR OUTCH
OUTRTS	AND #255
	RTS
TRMNOK	LDA INPFLG
	BEQ TRMNO1
	BMI GETDTL
	LDY #255
	BNE STCURL
GETDTL	LDA DATLIN
	LDY DATLIN+1
STCURL	STA CURLIN
	STY CURLIN+1
SNERR4	JMP SNERR
TRMNO1	LDA CHANNL
	BEQ DOAGIN
	LDX #ERRBD
	JMP ERROR
DOAGIN	LDA #<TRYAGN
	LDY #>TRYAGN
	JSR STROUT
	LDA OLDTXT
	LDY OLDTXT+1
	STA TXTPTR
	STY TXTPTR+1
	RTS
GET	JSR ERRDIR
	CMP #'#
	BNE GETTTY
	JSR CHRGET
	JSR GETBYT
	LDA #44
	JSR SYNCHR
	STX CHANNL
	JSR COIN
ZZ2=BUF+1
GETTTY	LDX #<ZZ2
ZZ3=BUF+2
	LDY #>ZZ3
	LDA #0
	STA BUF+1
	LDA #64
	JSR INPCO1
	LDX CHANNL
	BNE IORELE
	RTS
INPUTN	JSR GETBYT
	LDA #44
	JSR SYNCHR
	STX CHANNL
	JSR COIN
	JSR NOTQTI
IODONE	LDA CHANNL
IORELE	JSR CLSCHN
	LDX #0
	STX CHANNL
	RTS
INPUT	CMP #34
	BNE NOTQTI
	JSR STRTXT
	LDA #59
	JSR SYNCHR
	JSR STRPRT
NOTQTI	JSR ERRDIR
	LDA #44
	STA BUF-1
GETAGN	JSR QINLIN
	LDA CHANNL
	BEQ BUFFUL
	JSR READST
	AND #2
	BEQ BUFFUL
	JSR IODONE
	JMP DATA
BUFFUL	LDA BUF
	BNE INPCON
	LDA CHANNL
	BNE GETAGN
	JSR DATAN
	JMP ADDON
QINLIN	LDA CHANNL
	BNE GINLIN
	JSR OUTQST
	JSR OUTSPC
GINLIN	JMP INLIN
READ	LDX DATPTR
	LDY DATPTR+1
	.BYT $A9
	TYA
	.BYT $2C
INPCON	LDA #0
INPCO1	STA INPFLG
	STX INPPTR
	STY INPPTR+1
INLOOP	JSR PTRGET
	STA FORPNT
	STY FORPNT+1
	LDA TXTPTR
	LDY TXTPTR+1
	STA VARTXT
	STY VARTXT+1
	LDX INPPTR
	LDY INPPTR+1
	STX TXTPTR
	STY TXTPTR+1
	JSR CHRGOT
	BNE DATBK1
	BIT INPFLG
	BVC QDATA
	JSR CGETL
	STA BUF
ZZ4=BUF-1
	LDX #<ZZ4
	LDY #>ZZ4
	BNE DATBK
QDATA	BMI DATLOP
	LDA CHANNL
	BNE GETNTH
	JSR OUTQST
GETNTH	JSR QINLIN
DATBK	STX TXTPTR
	STY TXTPTR+1
.END