-
Notifications
You must be signed in to change notification settings - Fork 0
/
meson.build
182 lines (159 loc) · 4.27 KB
/
meson.build
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
project('titania', 'c',
license : 'MPL-2',
meson_version : '>=1.3.0',
version : '2.2.3',
default_options : [
'c_std=c2x',
'warning_level=3',
'default_library=both'
]
)
compiler = meson.get_compiler('c')
linker = meson.get_compiler('c')
args = compiler.get_supported_arguments(
'-fanalyzer',
'-Wall',
'-Wextra',
'-pedantic',
'-Wno-unused-variable',
'-Wno-unused-parameter',
'-fcx-limited-range',
'-ffp-contract=on',
'/wd4820'
)
if get_option('buildtype') == 'custom'
args += compiler.get_supported_arguments(
'-march=native',
'-mtune=native'
)
endif
if get_option('buildtype') == 'debug'
args += compiler.get_supported_arguments('-Werror')
endif
has_nullptr = false
if compiler.compiles('int main(void) { return nullptr == 0; }\n', name : 'has nullptr', args : args, werror : true)
has_nullptr = true
endif
pack_test = '''
#pragma pack(push, 1)
struct nya {
char a;
int b;
};
static_assert(sizeof(struct nya) == 5, "");
#pragma pack(pop)
'''
has_pack = false
if compiler.compiles(pack_test, name : 'has pack', args : args, werror : true)
has_pack = true
endif
stdc_test = '''
#pragma STDC FP_CONTRACT ON
#pragma STDC CX_LIMITED_RANGE ON
'''
has_stdc_flags = false
if compiler.compiles(stdc_test, name : 'has stdc flags', args : args, werror : true)
has_stdc_flags = true
endif
config_file = configure_file(
output : 'titania_config.h',
configuration : configuration_data({
'TITANIA_MAX_CONTROLLERS' : get_option('titania_max_controllers'),
'TITANIA_PROJECT_NAME' : '"' + meson.project_name() + '"',
'TITANIA_PROJECT_VERSION' : '"' + meson.project_version() + '"'
}),
install : true,
install_dir : get_option('includedir')
)
configure_file(
output : 'titania_config_internal.h',
configuration : configuration_data({
'TITANIA_HAS_NULLPTR' : has_nullptr,
'TITANIA_HAS_PACK' : has_pack,
'TITANIA_HAS_STDC_FLAGS': has_stdc_flags
})
)
hidapi = dependency('hidapi', version : '>=0.13.0', required : false)
if not hidapi.found()
hidapi = dependency('hidapi')
endif
titania_inc = include_directories('include/')
titania_lib = library(meson.project_name(), [
'src/access.c',
'src/crc.c',
'src/enums.c',
'src/edge.c',
'src/hid.c',
'src/trans.c',
'src/unicode.c'
],
dependencies : [hidapi],
gnu_symbol_visibility : 'hidden',
c_args : [args, '-DTITANIA_EXPORTING'],
install : true,
soversion : meson.project_version(),
include_directories : titania_inc
)
titania_dep = declare_dependency(link_with : titania_lib, include_directories : titania_inc)
if get_option('titania_ctl')
json = dependency('json', version : '>=1.0')
executable('titaniactl', [
'src/ctl/main.c',
'src/ctl/modes/access.c',
'src/ctl/modes/bench.c',
'src/ctl/modes/bt.c',
'src/ctl/modes/dump.c',
'src/ctl/modes/edge.c',
'src/ctl/modes/led.c',
'src/ctl/modes/profile.c',
'src/ctl/modes/report.c',
'src/ctl/modes/test.c'
],
c_args : [args],
dependencies : [titania_dep, hidapi, json],
install : true)
endif
install_headers(['include/titania.h'], preserve_path : false)
if get_option('titania_man')
pandoc = find_program('pandoc', required : false)
if not pandoc.found()
warning('pandoc not found, building man pages will not be possible')
else
pandoc_commands = [pandoc, '-s', '-t', 'man', '-f', 'gfm+definition_lists', '-o']
custom_target(
'dualsense-hid.7',
output : 'dualsense-hid.7',
input : 'man/dualsense-hid.7.md',
build_always_stale : true,
install : true,
install_dir : join_paths(get_option('mandir'), 'man7'),
command : [pandoc_commands, '@OUTPUT@', '@INPUT@']
)
custom_target(
'titania.1',
output : 'titania.1',
input : 'man/titania.1.md',
build_always_stale : true,
install : true,
install_dir : join_paths(get_option('mandir'), 'man1'),
command : [pandoc_commands, '@OUTPUT@', '@INPUT@']
)
if get_option('titania_ctl')
custom_target(
'titaniactl.1',
output : 'titaniactl.1',
input : 'man/titaniactl.1.md',
build_always_stale : true,
install : true,
install_dir : join_paths(get_option('mandir'), 'man1'),
command : [pandoc_commands, '@OUTPUT@', '@INPUT@']
)
endif
endif
endif
import('pkgconfig').generate(
titania_lib,
description : 'unofficial dualsense and playstation access library',
url : 'https://git.sr.ht/~chronovore/titania',
version : meson.project_version()
)